**LAMPIRAN**

Lampiran 1. Input *file* tablo model CGE AGROINDUSTRI 2

Lampiran 2. Input *file* c*losure* jangka pendek dan jangka panjang 27

Lampiran 3. Komponen data dasar 35 sektor 28

Lampiran 4. Nilai PDB Indonesia dari sisi pengeluaran dan sisi pendapatan 30

Lampiran 5. Nilai penjualan sektoral 31

Lampiran 6. Biaya produksi sektoral 33

Lampiran 1. Input *file* tablo model CGE AGROINDUSTRI

!---------------------------------------------------------------------------------------------!

!TABLO Input file for the agroindustri indonesia model: 35 sectors !

!---------------------------------------------------------------------------------------------!

! Excerpt 1 of TABLO input file: !

! Definitions of sets !

Set COM # Commodities #

(Padi, TanMakLn, Karet, Tebu, KelapaSawit, Tembakau, Kopi, Teh,

Kakao, TanKebLn, Peternakan, Kayu, HasHutln, Perikanan, Pertambangan,

Makanan, IndKlpSwt, Beras, Terigu, Gula, Minuman, Rokok, Pemintalan,

TeksPakKlt, BambuKyRotan, KrtsKrbon, PpkPestisida, Kimia, OlahKaret, Semen,

IndustriLain, ListrkGasAir, Bangunan, DagResHot, Jasa);

Set SRC # Source of commodities # (Dom, Imp); !s!

Set IND # Industries #

(Padi, TanMakLn, Karet, Tebu, KelapaSawit, Tembakau, Kopi, Teh,

Kakao, TanKebLn, Peternakan, Kayu, HasHutln, Perikanan, Pertambangan,

Makanan, IndKlpSwt, Beras, Terigu, Gula, Minuman, Rokok, Pemintalan,

TeksPakKlt, BambuKyRotan, KrtsKrbon, PpkPestisida, Kimia, OlahKaret, Semen,

IndustriLain, ListrkGasAir, Bangunan, DagResHot, Jasa);

Set OCC # ccupation types # (Unskilled, Skilled); !o!

Set MAR # Margin commodities # (DagResHot, Jasa);

Subset MAR is subset of COM;

Set NONMAR # Non-margin commodities # = COM - MAR; ! n !

Set EXOGINV # 'exogenous' investment industries #

(Pertambangan, ListrkGasAir, Bangunan, DagResHot, Jasa);

Subset EXOGINV is Subset of IND;

Set ENDOGINV # 'endogenous' investment industries # = IND - EXOGINV;

SET HH #household types# (agr1-agr2, rural1-rural3, urban1-urban3);

SET AGRIFAC # Agricultural factors #(unskilled,varcap,land,fert) ;

SET N\_AGRIFAC # Non-agricultural factors # (labcomp, fixcap, varcap) ;

SET FACNF # All factors except fertiliser #

(skilled, unskilled,fixcap,varcap,land);

SET KAP # Types of capital #(fixcap ,varcap ) ;

SET AGFACNF #Agri. factors excluding fertiliser# (unskilled,varcap,land);

SET AGIND (Padi, TanMakLn, Karet, Tebu, KelapaSawit, Tembakau, Kopi, Teh, Kakao,

TanKebLn, Peternakan, Kayu, HasHutln, Perikanan);

SET FERTIL (PpkPestisida);

SUBSET

AGFACNF IS SUBSET OF AGRIFAC;

AGFACNF IS SUBSET OF FACNF;

KAP IS SUBSET OF FACNF;

OCC IS SUBSET OF FACNF;

AGIND IS SUBSET OF IND;

FERTIL IS SUBSET OF COM;

KAP IS SUBSET OF N\_AGRIFAC;

SET N\_AGIND = IND - AGIND;

SET NONFERT = COM - FERTIL;

! Excerpt 2 of TABLO input file: !

! Variables relating to commodity flows !

Variable

! Basic Demands for commodities (excluding margin demands) !

(all,c,COM)(all,s,SRC)(all,i,IND) x1(c,s,i) # Intermediate basic demands #;

(all,c,COM)(all,s,SRC)(all,i,IND) x2(c,s,i) # Investment basic demands #;

(all,c,COM)(all,s,SRC)(all,h,HH) x3(c,s,h) # Household basic demands #;

(all,c,COM) x4(c) # Export basic demands #;

(all,c,COM)(all,s,SRC) x5(c,s) # Government basic demands #;

(change) (all,c,COM)(all,s,SRC) delx6(c,s) # Inventories demands #;

(all,c,COM)(all,s,SRC) p0(c,s) # Basic prices by commodity and source #;

! Technical or Taste Change Variables affecting Basic Demands !

(all,c,COM)(all,s,SRC)(all,i,IND) a1(c,s,i) # Intermediate basic tech change #;

(all,c,COM)(all,s,SRC)(all,i,IND) a2(c,s,i) # Investment basic tech change #;

(all,c,COM)(all,s,SRC) a3(c,s) # Household basic taste change #;

(all,c,COM)(all,s,SRC) f5(c,s) # Government demand shift #;

! Margin Usage on Basic Flows !

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR) x1mar(c,s,i,m)# Intermediate margin demands #;

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR x2mar(c,s,i,m)# Investment margin demands #;

(all,c,COM)(all,s,SRC)(all,m,MAR)(all,h,HH) x3mar(c,s,m,h) # Household margin demands #;

(all,c,COM)(all,m,MAR) x4mar(c,m) # Export margin demands #;

(all,c,COM)(all,s,SRC)(all,m,MAR) x5mar(c,s,m) # Government margin demands #;

! Technical Change in Margins Usage !

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR) a1mar(c,s,i,m) # Intermediate margin tech change #;

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR) a2mar(c,s,i,m) # Investment margin tech change #;

(all,c,COM)(all,s,SRC)(all,m,MAR) a3mar(c,s,m) # Household margin tech change #;

(all,c,COM)(all,m,MAR) a4mar(c,m) # Export margin tech change #;

(all,c,COM)(all,s,SRC)(all,m,MAR) a5mar(c,s,m) # Governmnt margin tech change #;

! Powers of Commodity Taxes on Basic Flows !

(all,c,COM)(all,s,SRC)(all,i,IND) t1(c,s,i) # Power of tax on intermediate #;

(all,c,COM)(all,s,SRC)(all,i,IND) t2(c,s,i) # Power of tax on investment #;

(all,c,COM)(all,s,SRC) t3(c,s) # Power of tax on household #;

(all,c,COM) t4(c) # Power of tax on export #;

(all,c,COM)(all,s,SRC) t5(c,s) # Power of tax on government #;

! Purchaser's Prices (including margins and taxes) !

(all,c,COM)(all,s,SRC)(all,i,IND) p1(c,s,i)# Purchaser's price, intermediate #;

(all,c,COM)(all,s,SRC)(all,i,IND) p2(c,s,i)# Purchaser's price, investment #;

(all,c,COM)(all,s,SRC)(all,h,HH) p3(c,s,h) # Purchaser's price, household #;

(all,c,COM) p4(c) # Purchaser's price, exports rupiah #;

(all,c,COM)(all,s,SRC) p5(c,s) # Purchaser's price, government #;

! Excerpt 3 of TABLO input file: !

! Variables for primary-factor flows, commodity supplies and import duties !

! Variables relating to usage of labour, occupation o, in industry i !

(all,i,IND)(all,o,OCC) x1lab(i,o) # Employment by industry and occupation #;

(all,i,IND)(all,o,OCC) p1lab(i,o) # Wages by industry and occupation #;

!(all,i,IND) a1lab\_o(i) # Labor augmenting technical change #;

(all,i,IND)(all,o,OCC) f1lab(i,o) # Wage shift variable #;!

! Variables relating to usage of fixed capital in industry i !

(all,i,IND) x1cap(i) # Current capital stock #;

(all,i,IND) p1cap(i) # Rental price of capital #;

!(all,i,IND) a1cap(i) # Capital augmenting technical change #;!

! Variables relating to usage of land !

(all,i,AGIND) x1lnd(i) # Use of land #;

(all,i,AGIND) p1lnd(i) # Rental price of land #;

!(all,i,IND) a1lnd(i) # Land augmenting technical change #;!

! Variables relating to "Other Costs" !

(all,i,IND) x1oct(i) # Demand for "other cost" tickets #;

(all,i,IND) p1oct(i) # Price of "other cost" tickets #;

(all,i,IND) a1oct(i) # "other cost" ticket augmenting techncal change#;

(all,i,IND) f1oct(i) # Shift in price of "other cost" tickets #;

! Variables relating to commodity supplies, import duties and stocks !

(all,c,COM)(all,i,IND) q1(c,i) # Output by commodity and industry #;

(all,c,COM) t0imp(c) # Power of tariff #;

(change)

(all,c,COM)(all,s,SRC) fx6(c,s) # Shifter on rule for stocks #;

! Excerpt 4 of TABLO input file: !

! Variables describing composite commodities !

! Demands for import/domestic commodity composites !

(all,c,COM)(all,i,IND) x1\_s(c,i) # Intermediate use of imp/dom composite #;

(all,c,COM)(all,i,IND) x2\_s(c,i) # Investment use of imp/dom composite #;

(all,c,COM)(all,h,HH) x3\_s(c,h) # Household use of imp/dom composite #;

(all,c,COM)(all,h,HH) x3lux(c,h) # Household - supernumerary demands #;

(all,c,COM)(all,h,HH) x3sub(c,h) # Household - subsistence demands #;

! Effective Prices of import/domestic commodity composites !

(all,c,COM)(all,i,IND) p1\_s(c,i) # Price, intermediate imp/dom composite #;

(all,c,COM)(all,i,IND) p2\_s(c,i) # Price, investment imp/dom composite #;

(all,c,COM)(all,h,HH) p3\_s(c,h) # Price, household imp/dom composite #;

! Technical or Taste Change Variables for import/domestic composites !

(all,c,COM)(all,i,IND) a1\_s(c,i) # Tech change, int'mdiate imp/dom composite #;

(all,c,COM)(all,i,IND) a2\_s(c,i) # Tech change, investment imp/dom composite #;

(all,c,COM)(all,h,HH) a3\_s(c,h) # Taste change, h'hold imp/dom composite #;

(all,c,COM)(all,h,HH) a3lux(c,h) # Taste change, supernumerary demands #;

(all,c,COM)(all,h,HH) a3sub(c,h) # Taste change, subsistence demands #;

! Excerpt 5 of TABLO input file: !

! Miscellaneous vector variables !

Variable

(all,i,IND) a1prim(i) # All factor augmenting technical change #;

(all,i,IND) a1tot(i) # All input augmenting technical change #;

(all,i,IND) a2tot(i) # Neutral technical change - investment #;

(all,i,IND) employ(i) # Employment by industry #;

(all,c,COM) f0tax\_s(c) # General sales tax shifter #;

(all,c,COM) f4tax\_x(c) # General sales tax trad export shifter #;

(all,o,OCC) f1lab\_i\_x(o) # Skill-specific labour shifter #;

(all,c,COM) f4p(c) # Price (upward) shift in export demand schedule #;

(all,c,COM) f4q(c) # Quantity (right) shift in export demands #;

(All,c,COM) p0com(c) # Output price of locally-produced commodity #;

(all,c,COM) p0dom(c) # Basic price of domestic goods = p0(c,"dom") #;

(all,c,COM) p0imp(c) # Basic price of imported goods = p0(c,"imp") #;

(all,i,IND) p1lab\_o(i) # Price of labour composite #;

(all,o,OCC) p1lab\_i(o) # Price of labour for each skill #;

(all,i,IND) p1prim(i) # Effective price of primary factor composite #;

(all,i,IND) p1tot(i) # Average input/output price #;

(all,i,IND) p2tot(i) # Cost of unit of capital #;

(All,c,COM) pe(c) # Basic price of export commodity #;

(all,c,COM) pf0cif(c) # C.I.F. foreign currency import prices #;

(all,c,COM) x0com(c) # Output of commodities #;

(all,c,COM) x0dom(c) # Output of commodities for local market #;

(all,c,COM) x0imp(c) # Total supplies of imported goods #;

(all,o,OCC) x1lab\_i(o) # Employment by occupation #;

(all,o,OCC)(all,h,HH) x1lab\_i\_h(o,h) # Household labour supply #;

(all,i,IND) x1lab\_o(i) # Effective labour input #;

(all,i,IND) x1prim(i) # Primary factor composite #;

(all,i,IND) x1tot(i) # Activity level or value-added #;

(all,i,IND) x2tot(i) # Investment by using industry #;

! Excerpt 6 of TABLO input file: !

! Scalar or macro variables !

Variable

(change) delB # %(Balance of trade)/GDP #;

!employ\_i # Aggregate employment: wage bill weights #;!

!f1lab\_io # Overall wage shifter #;!

f1tax\_csi # Uniform % change in powers of taxes on intermediate usage #;

f2tax\_csi # Uniform % change in powers of taxes on investment #;

f3tax\_cs # Uniform % change in powers of taxes on household usage #;

f3tot # Ratio, consumption/income #;

(all,h,HH)f3tot\_h(h)# Ratio, consumption/income by hh#;

f4tax\_c # Uniform % change in powers of taxes on exports #;

f5tax\_cs # Uniform % change in powers of taxes on government usage #;

f5tot # Overall shift term for government demands #;

f5tot2 # Ratio between f5tot and x3tot #;

p0cif\_c # Imports price index, C.I.F., rupiah #;

p0gdpexp # GDP price index, expenditure side #;

p0imp\_c # Duty-paid imports price index, rupiah #;

p0realdev # Real devaluation #;

p0toft # Terms of trade #;

p1cap\_i # Average capital rental #;

p1lab\_io # Average nominal wage #;

p2tot\_i # Aggregate investment price index #;

p3tot # Consumer price index #;

p4tot # Exports price index #;

p5tot # Government price index #;

p6tot # Inventories price index #;

phi # Exchange rate, rupiah/$world #;

(all,h,HH)q(h) # Number of households #;

realwage # Average real wage #;

(all,h,HH)utility(h) # Utility per household #;

w0cif\_c # C.I.F. rupiah value of imports #;

w0gdpexp # Nominal GDP from expenditure side #;

w0gdpinc # Nominal GDP from income side #;

w0imp\_c # Value of imports plus duty #;

w0tar\_c # Aggregate tariff revenue #;

w0tax\_csi # Aggregate revenue from all indirect taxes #;

w1cap\_i # Aggregate payments to capital #;

w1lab\_io # Aggregate payments to labour #;

w1lnd\_i # Aggregate payments to land #;

w1oct\_i # Aggregate "other cost" ticket payments #;

w1tax\_csi # Aggregate revenue from indirect taxes on intermediate #;

w2tax\_csi # Aggregate revenue from indirect taxes on investment #;

w2tot\_i # Aggregate nominal investment #;

(all,h,HH)w3lux(h)# Total nominal supernumerary household expenditure #;

w3tax\_cs # Aggregate revenue from indirect taxes on households #;

(all,h,HH)w3tot\_hh(h)# Nominal total consumption, each household #;

(all,h,HH)x3tot\_hh(h)# Nominal total consumption, each household #;

(all,h,HH)p3tot\_hh(h)# Nominal total consumption, each household #;

w3tot # Nominal total household consumption #;

w4tax\_c # Aggregate revenue from indirect taxes on export #;

w4tot # rupiah border value of exports #;

w5tax\_cs # Aggregate revenue from indirect taxes on government #;

w5tot # Aggregate nominal value of government demands #;

w6tot # Aggregate nominal value of inventories #;

x0cif\_c # Import volume index, C.I.F. weights #;

x0gdpexp # Real GDP from expenditure side #;

x0imp\_c # Import volume index, duty-paid weights #;

x1cap\_i # Aggregate capital stock, rental weights #;

x1prim\_i # Aggregate output: value-added weights #;

x2tot\_i # Aggregate real investment expenditure #;

x3tot # Real household consumption #;

!x4\_ntrad # Quantity, non-traditional export aggregate #;!

x4tot # Export volume index #;

x5tot # Aggregate real government demands #;

x6tot # Aggregate real inventories #;

! Excerpt 7 of TABLO input file: !

! Data coefficients relating to basic commodity flows !

File MDATA # Data file #;

Coefficient ! Basic Flows of Commodities!

(all,c,COM)(all,s,SRC)(all,i,IND) V1BAS(c,s,i) # Intermediate basic flows #;

(all,c,COM)(all,s,SRC)(all,i,IND) V2BAS(c,s,i) # Investment basic flows #;

(all,c,COM)(all,s,SRC)(all,h,HH) V3BAS(c,s,h) # Household basic flows #;

(all,c,COM) V4BAS(c) # Export basic flows #;

(all,c,COM)(all,s,SRC) V5BAS(c,s) # Government basic flows #;

(all,c,COM)(all,s,SRC) V6BAS(c,s) # Inventories basic flows #;

Read

V1BAS from file MDATA header "1BAS";

V2BAS from file MDATA header "2BAS";

V3BAS from file MDATA header "3BAS";

V4BAS from file MDATA header "4BAS";

V5BAS from file MDATA header "5BAS";

V6BAS from file MDATA header "6BAS";

Update

(all,c,COM)(all,s,SRC)(all,i,IND) V1BAS(c,s,i) = p0(c,s)\*x1(c,s,i);

(all,c,COM)(all,s,SRC)(all,i,IND) V2BAS(c,s,i) = p0(c,s)\*x2(c,s,i);

(all,c,COM)(all,s,SRC)(all,h,HH) V3BAS(c,s,h) = p0(c,s)\*x3(c,s,h);

(all,c,COM) V4BAS(c) = pe(c)\*x4(c);

(all,c,COM)(all,s,SRC) V5BAS(c,s) = p0(c,s)\*x5(c,s);

Coefficient (all,c,COM)(all,s,SRC) LEVP0(c,s) # Levels basic prices #;

Formula (Initial) (all,c,COM)(all,s,SRC) LEVP0(c,s) = 1; ! arbitrary setting !

Update (all,c,COM)(all,s,SRC) LEVP0(c,s) = p0(c,s);

(change) (all,c,COM)(all,s,SRC)

V6BAS(c,s) = V6BAS(c,s)\*p0(c,s)/100 + LEVP0(c,s)\*delx6(c,s);

Coefficient ! Margin Flows!

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR)

V1MAR(c,s,i,m) # Intermediate margins #;

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR)

V2MAR(c,s,i,m) # Investment margins #;

(all,c,COM)(all,s,SRC)(all,m,MAR)(all,h,HH)

V3MAR(c,s,m,h) # Households margins #;

(all,c,COM)(all,m,MAR) V4MAR(c,m) # Export margins #;

(all,c,COM)(all,s,SRC)(all,m,MAR) V5MAR(c,s,m) # Government margins #;

Read

V1MAR from file MDATA header "1MAR";

V2MAR from file MDATA header "2MAR";

V3MAR from file MDATA header "3MAR";

V4MAR from file MDATA header "4MAR";

V5MAR from file MDATA header "5MAR";

Update

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR)

V1MAR(c,s,i,m) = p0dom(m)\*x1mar(c,s,i,m);

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR)

V2MAR(c,s,i,m) = p0dom(m)\*x2mar(c,s,i,m);

(all,c,COM)(all,s,SRC)(all,m,MAR)(all,h,HH)

V3MAR(c,s,m,h) = p0dom(m)\*x3mar(c,s,m,h);

(all,c,COM)(all,m,MAR)

V4MAR(c,m) = p0dom(m)\*x4mar(c,m);

(all,c,COM)(all,s,SRC)(all,m,MAR)

V5MAR(c,s,m) = p0dom(m)\*x5mar(c,s,m);

! Excerpt 8 of TABLO input file: !

! Data coefficients relating to commodity taxes !

Coefficient ! Taxes on Basic Flows!

(all,c,COM)(all,s,SRC)(all,i,IND) V1TAX(c,s,i) # Taxes on intermediate #;

(all,c,COM)(all,s,SRC)(all,i,IND) V2TAX(c,s,i) # Taxes on investment #;

(all,c,COM)(all,s,SRC)(all,h,HH) V3TAX(c,s,h) # Taxes on households #;

(all,c,COM) V4TAX(c) # Taxes on export #;

(all,c,COM)(all,s,SRC) V5TAX(c,s) # Taxes on government #;

Read

V1TAX from file MDATA header "1TAX";

V2TAX from file MDATA header "2TAX";

V3TAX from file MDATA header "3TAX";

V4TAX from file MDATA header "4TAX";

V5TAX from file MDATA header "5TAX";

Update (change) (all,c,COM)(all,s,SRC)(all,i,IND)

V1TAX(c,s,i) = V1TAX(c,s,i)\* [x1(c,s,i) + p0(c,s)]/100 + [V1BAS(c,s,i)+V1TAX(c,s,i)]\*t1(c,s,i)/100;

Update (change) (all,c,COM)(all,s,SRC)(all,i,IND)

V2TAX(c,s,i) = V2TAX(c,s,i)\* [x2(c,s,i) + p0(c,s)]/100 +

[V2BAS(c,s,i)+V2TAX(c,s,i)]\*t2(c,s,i)/100;

Update (change) (all,c,COM)(all,s,SRC)(all,h,HH)

V3TAX(c,s,h) = V3TAX(c,s,h)\* [x3(c,s,h) + p0(c,s)]/100 +

[V3BAS(c,s,h)+V3TAX(c,s,h)]\*t3(c,s)/100;

Update (change) (all,c,COM)

V4TAX(c) = V4TAX(c)\* [x4(c) + pe(c)]/100 +

[V4BAS(c)+V4TAX(c)]\*t4(c)/100;

Update (change) (all,c,COM)(all,s,SRC)

V5TAX(c,s) = V5TAX(c,s)\*[x5(c,s) + p0(c,s)]/100 +

[V5BAS(c,s)+V5TAX(c,s)]\*t5(c,s)/100;

! Excerpt 9 of TABLO input file: !

! Data coefficients relating to primary-factor flows !

Coefficient ! Primary Factor and Other Industry costs!

(all,k,KAP)(all,i,N\_AGIND) V1CAPN(k,i) # Capital rentals by mobility #;

(all,i,AGIND) V1CAPA (i) # Capital rentals, agri. #;

(all,i,IND) V1CAP(i) # Capital rentals #;

(all,i,IND)(all,o,OCC) V1LAB(i,o) # Wage bill matrix #;

(all,i,IND) V1LND(i) # Land rentals #;

(all,i,IND) V1OCT(i) # Other cost tickets #;

Read

V1CAPN from file MDATA header "1CAP";

V1CAPA from file MDATA header "1CAG";

V1LAB from file MDATA header "1LAB";

V1LND from file MDATA header "1LND";

V1OCT from file MDATA header "1OCT";

Update

!(all,i,IND) V1CAP(i) = p1cap(i)\*x1cap(i);!

(all,i,IND)(all,o,OCC) V1LAB(i,o) = p1lab(i,o)\*x1lab(i,o);

(all,i,AGIND) V1LND(i) = p1lnd(i)\*x1lnd(i);

(all,i,IND) V1OCT(i) = p1oct(i)\*x1oct(i);

! Excerpt 10 of TABLO input file: !

! Data coefficients relating to commodity outputs and import duties !

Coefficient (all,c,COM)(all,i,IND) MAKE(c,i) # Multiproduction matrix #;

Read MAKE from file MDATA header "MAKE";

Update (all,c,COM)(all,i,IND) MAKE(c,i)= p0com(c)\*q1(c,i);

Coefficient (all,c,COM) V0TAR(c) # Tariff revenue #;

Read V0TAR from file MDATA header "0TAR";

Coefficient (all,c,COM) V0IMP(c) # Total basic-value imports of good c #;

! V0IMP(c) is needed to update V0TAR: it is declared now and defined later !

Update (change) (all,c,COM)

V0TAR(c) = V0TAR(c)\*[x0imp(c)+pf0cif(c)+phi]/100 + V0IMP(c)\*t0imp(c)/100;

! Excerpt 11 of TABLO input file: !

! Aggregates and shares of flows at purchasers' prices !

Coefficient ! Flows at Purchasers prices !

(all,c,COM)(all,s,SRC)(all,i,IND) V1PUR(c,s,i) # Intermediate purch. value #;

(all,c,COM)(all,s,SRC)(all,i,IND) V2PUR(c,s,i) # Investment purch. value #;

(all,c,COM)(all,s,SRC)(all,h,HH) V3PUR(c,s,h) # Households purch. value #;

(all,c,COM) V4PUR(c) # Export purch. value #;

(all,c,COM)(all,s,SRC) V5PUR(c,s) # Government purch. value #;

Formula

(all,c,COM)(all,s,SRC)(all,i,IND)

V1PUR(c,s,i) = V1BAS(c,s,i) + V1TAX(c,s,i) + sum{m,MAR, V1MAR(c,s,i,m) };

(all,c,COM)(all,s,SRC)(all,i,IND)

V2PUR(c,s,i) = V2BAS(c,s,i) + V2TAX(c,s,i) + sum{m,MAR, V2MAR(c,s,i,m) };

(all,c,COM)(all,s,SRC)(all,h,HH)

V3PUR(c,s,h) = V3BAS(c,s,h) + V3TAX(c,s,h)

+ sum{m,MAR,V3MAR(c,s,m,h) };

(all,c,COM)

V4PUR(c) = V4BAS(c) + V4TAX(c) + sum{m,MAR, V4MAR(c,m) };

(all,c,COM)(all,s,SRC)

V5PUR(c,s) = V5BAS(c,s) + V5TAX(c,s) + sum{m,MAR, V5MAR(c,s,m) };

Coefficient ! Flows at Purchaser's prices: Domestic + Imported Totals !

(all,c,COM)(all,i,IND) V1PUR\_S(c,i) # Dom+imp intermediate purch. value #;

(all,c,COM)(all,i,IND) V2PUR\_S(c,i) # Dom+imp investment purch. value #;

(all,c,COM) V1PUR\_SI(c) # Dom+imp intermediate purch. value #;

(all,c,COM) V2PUR\_SI(c) # Dom+imp investment purch. value #;

(all,c,COM)(all,h,HH) V3PUR\_S(c,h) # Dom+imp households purch. value #;

Formula

(all,c,COM)(all,i,IND) V1PUR\_S(c,i) = sum{s,SRC, V1PUR(c,s,i) };

(all,c,COM)(all,i,IND) V2PUR\_S(c,i) = sum{s,SRC, V2PUR(c,s,i) };

(all,c,COM) V1PUR\_SI(c) = sum{i,IND, V1PUR\_S(c,i) };

(all,c,COM) V2PUR\_SI(c) = sum{i,IND, V2PUR\_S(c,i) };

(all,c,COM)(all,h,HH) V3PUR\_S(c,h) = sum{s,SRC,V3PUR(c,s,h)};

Coefficient ! Source Shares in Flows at Purchaser's prices !

(all,c,COM)(all,s,SRC)(all,i,IND) S1(c,s,i) # Intermediate source shares #;

(all,c,COM)(all,s,SRC)(all,i,IND) S2(c,s,i) # Investment source shares #;

(all,c,COM)(all,s,SRC)(all,h,HH) S3(c,s,h) # Households source shares #;

Zerodivide Default 0.5;

Formula

(all,c,COM)(all,s,SRC)(all,i,IND) S1(c,s,i) = V1PUR(c,s,i) / V1PUR\_S(c,i);

(all,c,COM)(all,s,SRC)(all,i,IND) S2(c,s,i) = V2PUR(c,s,i) / V2PUR\_S(c,i);

(all,c,COM)(all,s,SRC)(all,h,HH) S3(c,s,h) = V3PUR(c,s,h)/V3PUR\_S(c,h);

Zerodivide Off;

! Excerpt 12 of TABLO input file: !

! Cost and usage aggregates !

Coefficient ! Industry-Specific Cost Totals !

(all,f,AGRIFAC)(all,i,AGIND)V1FAC(f,i)# Total factor input to ind. i, agri.#;

(all,f,N\_AGRIFAC)(all,i,N\_AGIND)V1FACO(f,i) # Total factor input non-agri. #;

(all,i,IND) V1LAB\_O(i) # Total labour bill in industry i #;

(all,i,IND) V1PRIM(i) # Total factor input to industry i#;

(all,i,IND) V1TOT(i) # Total cost of industry i #;

(all,i,IND) V2TOT(i) # Total capital created for industry i #;

(all,o,OCC) V1LAB\_I(o) # Total wages, occupation o #;

Formula

(all,i,IND) V1LAB\_O(i) = sum{o,OCC, V1LAB(i,o) };

(all,i,AGIND) V1CAP(i) = V1CAPA(i);

(all,i,AGIND) V1FAC("unskilled",i) = V1LAB\_O(i);

(all,i,AGIND) V1FAC("varcap",i) = V1CAPA(i);

(all,i,AGIND) V1FAC("fert",i) =V1PUR\_S("PpkPestisida",i);

(all,i,AGIND) V1FAC("land",i) =V1LND(i);

(all,i,N\_AGIND)V1CAP(i) = sum{k,KAP,V1CAPN(k,i) };

(all,k,KAP)(all,i,N\_AGIND) V1FACO(k,i) = V1CAPN(k,i);

(all,i,N\_AGIND) V1FACO("labcomp",i) =V1LAB\_O(i);

(all,i,AGIND) V1PRIM(i) = sum{f,AGRIFAC,V1FAC(f,i)};

(all,i,N\_AGIND) V1PRIM(i) = sum{f,N\_AGRIFAC,V1FACO(f,i)};

(all,i,AGIND)V1TOT(i) = V1PRIM(i) + V1OCT(i) + sum{c,NONFERT,V1PUR\_S(c,i) };

(all,i,N\_AGIND)V1TOT(i) = V1PRIM(i) + V1OCT(i) + sum{c,COM, V1PUR\_S(c,i) };

(all,i,IND) V2TOT(i) = sum{c,COM, V2PUR\_S(c,i) };

(all,o,OCC) V1LAB\_I(o) = sum{i,IND, V1LAB(i,o) };

Coefficient (all,c,COM) MARSALES(c) # Total usage for margins purposes #;

Formula (all,m,MAR) MARSALES(m) =

sum{c,COM, V4MAR(c,m) +

sum{s,SRC,sum{h,HH,V3MAR(c,s,m,h)} + V5MAR(c,s,m) +

sum{i,IND, V1MAR(c,s,i,m) + V2MAR(c,s,i,m) }}};

Formula (all,n,NONMAR) MARSALES(n) = 0.0;

Coefficient (all,c,COM) DOMSALES(c) # Total sales to local market #;

Formula (all,c,COM)

DOMSALES(c) = sum{i,IND, V1BAS(c,"dom",i) + V2BAS(c,"dom",i) }

+ sum(h,HH,V3BAS(c,"dom",h)) + V5BAS(c,"dom") + V6BAS(c,"dom") +MARSALES(c);

Coefficient (all,c,COM) SALES(c) # Total sales of domestic commodities #;

Formula (all,c,COM) SALES(c) = DOMSALES(c) + V4BAS(c);

! Coefficient (all,c,COM) V0IMP(c) # Total basic-value imports of good c #; !

! above had to be declared prior to V0TAR update statement!

Formula (all,c,COM) V0IMP(c) =

sum{i,IND, V1BAS(c,"imp",i) + V2BAS(c,"imp",i) }

+ sum(h,HH,V3BAS(c,"imp",h)) + V5BAS(c,"imp") + V6BAS(c,"imp");

Coefficient (all,c,COM) V0CIF(c) # Total ex-duty imports of good c #;

Formula (all,c,COM) V0CIF(c) = V0IMP(c) - V0TAR(c);

! Excerpt 13 of TABLO input file: !

! Income-Side Components of GDP !

Coefficient ! Total indirect tax revenues !

V1TAX\_CSI # Total intermediate tax revenue #;

V2TAX\_CSI # Total investment tax revenue #;

V3TAX\_CS # Total households tax revenue #;

V4TAX\_C # Total export tax revenue #;

V5TAX\_CS # Total government tax revenue #;

V0TAR\_C # Total tariff revenue #;

V0TAX\_CSI # Total indirect tax revenue #;

Formula

V1TAX\_CSI = sum{c,COM, sum{s,SRC, sum{i,IND, V1TAX(c,s,i) }}};

V2TAX\_CSI = sum{c,COM, sum{s,SRC, sum{i,IND, V2TAX(c,s,i) }}};

V3TAX\_CS = sum{c,COM, sum{s,SRC, sum{h,HH, V3TAX(c,s,h) }}};

V4TAX\_C = sum{c,COM, V4TAX(c) };

V5TAX\_CS = sum{c,COM, sum{s,SRC, V5TAX(c,s) }};

V0TAR\_C = sum{c,COM, V0TAR(c) };

V0TAX\_CSI = V1TAX\_CSI + V2TAX\_CSI + V3TAX\_CS + V4TAX\_C + V5TAX\_CS + V0TAR\_C;

Coefficient ! All-Industry Factor Cost Aggregates !

V1CAP\_I # Total payments to capital #;

V1LAB\_IO # Total payments to labour #;

V1LND\_I # Total payments to land #;

V1OCT\_I # Total other cost ticket payments #;

V1PRIM\_I # Total primary factor payments#;

V0GDPINC # Nominal GDP from income side #;

Formula

V1CAP\_I = sum{i,IND, V1CAP(i) };

V1LAB\_IO = sum{i,IND, V1LAB\_O(i) };

V1LND\_I = sum{i,IND, V1LND(i) };

V1OCT\_I = sum{i,IND, V1OCT(i) };

V1PRIM\_I = V1LAB\_IO + V1CAP\_I + V1LND\_I;

V0GDPINC = V1PRIM\_I + V1OCT\_I + V0TAX\_CSI;

! Excerpt 14 of TABLO input file: !

! Expenditure-side components of GDP !

Coefficient ! Expenditure Aggregates at Purchaser's Prices !

V0CIF\_C # Total rupiah import costs, excluding tariffs #;

V0IMP\_C # Total basic-value imports (includes tariffs) #;

V2TOT\_I # Total investment usage #;

(all,h,HH)V3TOT\_HH(h) # Total purchases by each households #;

V3TOT # Total purchases by households #;

V4TOT # Total export earnings #;

V5TOT # Total value of government demands #;

V6TOT # Total value of inventories #;

V0GDPEXP # Nominal GDP from expenditure side #;

Formula

V0CIF\_C = sum{c,COM, V0CIF(c) };

V0IMP\_C = sum{c,COM, V0IMP(c) };

V2TOT\_I = sum{i,IND, V2TOT(i) };

(all,h,HH)V3TOT\_HH(h) = sum{c,COM, V3PUR\_S(c,h) };

V3TOT = sum(h,HH,V3TOT\_HH(h));

V4TOT = sum{c,COM, V4PUR(c) };

V5TOT = sum{c,COM, sum{s,SRC, V5PUR(c,s) }};

V6TOT = sum{c,COM, sum{s,SRC, V6BAS(c,s) }};

V0GDPEXP = V3TOT + V2TOT\_I + V5TOT + V6TOT + V4TOT - V0CIF\_C;

Coefficient TINY # Small number to prevent singular matrix #;

Formula TINY = 0.000000000001;

! Excerpt 15 of TABLO input file: !

! Occupational composition of labour demand !

!$ Problem: for each industry i, minimize labour cost !

!$ sum{o,OCC, P1LAB(i,o)\*X1LAB(i,o) } !

!$ such that X1LAB\_O(i) = CES( All,o,OCC: X1LAB(i,o) ) !

Coefficient (all,i,IND) SIGMA1LAB(i) # CES substitution between skill types #;

Read SIGMA1LAB from file MDATA header "SLAB";

Equation E\_x1lab # Demand for labour by industry and skill group #

(all,i,IND)(all,o,OCC)

x1lab(i,o) = x1lab\_o(i) - SIGMA1LAB(i)\*[p1lab(i,o) - p1lab\_o(i)];

Equation E\_p1lab\_o # Price to each industry of labour composite #

(all,i,IND)

[TINY+V1LAB\_O(i)]\*p1lab\_o(i) = sum{o,OCC, V1LAB(i,o)\*p1lab(i,o) };

! Excerpt 16 of TABLO input file: !

! Excerpt 16A: Primary factor proportions !

!Translog unit cost function. This is outlined in appendix G.

It is used to preserve a matrix of factor demand elasticities without the

restrictions of CRESH or CDE. See p. 133-141 of the Black Book.!

Variable

(all,f,AGRIFAC)(all,i,AGIND)x1fac(f,i) # Primary factor demands, agriculture #;

(all,f,AGRIFAC)(all,i,AGIND)p1fac(f,i) # Primary factor pirces, agriculture #;

(all,f,AGRIFAC)(all,i,AGIND)a1fac(f,i) # Primary factor tech. change, agri. #;

(all,f,N\_AGRIFAC)(all,i,N\_AGIND)a1faco(f,i)# Prim. factor tech. change, other #;

(all,f,N\_AGRIFAC)(all,i,N\_AGIND)x1faco(f,i) # Primary factor demands, other #;

(all,f,N\_AGRIFAC)(all,i,N\_AGIND)p1faco(f,i) # Primary factor price, other #;

Coefficient

(all,f,AGRIFAC) (all,i,AGIND) V1FACSH(f,i) #Agri. ind. factor share#;

(all,f,AGRIFAC)(all,v,AGRIFAC)(all,i,AGIND)

SHR\_FAC(f,v,i)#Agri. industry modified factor share (for translog)#;

(all,f,AGRIFAC)(all,v,AGRIFAC)(all,i,AGIND)

BETA\_A(f,v,i)#Factor demand elasticities, agri.#;

(all,f,N\_AGRIFAC)(all,i,N\_AGIND) V1FACSH\_N(f,i) #Non-ag ind. factor share#;

(all,f,N\_AGRIFAC)(all,v,N\_AGRIFAC)(all,i,N\_AGIND)

SHR\_FAC\_N(f,v,i)#Non-ag. ind. modified factor share (for translog)#;

(all,f,N\_AGRIFAC)(all,v,N\_AGRIFAC)(all,i,N\_AGIND)

BETA\_N(f,v,i)#Factor demand elasticities, non-ag.#;

Read

BETA\_A from file MDATA header "ALPH";

BETA\_N from file MDATA header "ALP2";

Zerodivide Default 0.33;

Formula !calculate the modified cost shares, appendix G, equation G.17!

(all,f,AGRIFAC)(all,i,AGIND)V1FACSH(f,i)=V1FAC(f,i)/sum{g,AGRIFAC,V1FAC(g,i)};

(all,f,N\_AGRIFAC) (all,i,N\_AGIND)V1FACSH\_N(f,i)=

V1FACO(f,i)/sum{g,N\_AGRIFAC,V1FACO(g,i)};

Zerodivide Default 0.25;

Formula

(all,f,AGRIFAC)(all,v,AGRIFAC)(all,i,AGIND)SHR\_FAC(f,v,i)=

V1FACSH(v,i) + BETA\_A(f,v,i)/V1FACSH(f,i);

(all,f,N\_AGRIFAC)(all,v,N\_AGRIFAC)(all,i,N\_AGIND)SHR\_FAC\_N(f,v,i)=

V1FACSH\_N(v,i) + BETA\_N(f,v,i)/V1FACSH\_N(f,i);

Zerodivide off;

Coefficient (all,i,IND)SIGMA1PRIM(i);

(all,i,IND)TRNL(i);

(all,i,IND)CESFORM(i);

Read TRNL from file MDATA header "TRNL";

Formula (all,i,IND)SIGMA1PRIM(i)=0.5; !CES alternative!

(all,i,IND)CESFORM(i) = 1 - TRNL(i); !if TRNL =0, CES functional form!

Equation E\_x1fac # Primary factor demands, agriculture # ! equation G.16!

(all,f,AGRIFAC)(all,i,AGIND)x1fac(f,i) - a1fac(f,i)=

x1prim(i) - TRNL(i)\*[p1fac(f,i) - Sum{v,AGRIFAC,SHR\_FAC(f,v,i)\*p1fac(v,i)}]

- TRNL(i)\*[a1fac(f,i) - Sum{v,AGRIFAC,SHR\_FAC(f,v,i)\*a1fac(v,i)}]

- CESFORM(i)\*SIGMA1PRIM(i)\*[p1fac(f,i) + a1fac(f,i) -p1prim(i)] ;

Equation E\_x1faco # Primary factor demands, non-agriculture # ! equation G.16!

(all,f,N\_AGRIFAC)(all,i,N\_AGIND)x1faco(f,i) - a1faco(f,i)=

x1prim(i)-TRNL(i)\*[p1faco(f,i) - Sum{v,N\_AGRIFAC,SHR\_FAC\_N(f,v,i)\*p1faco(v,i)}]

-TRNL(i)\*[a1faco(f,i) - Sum{v,N\_AGRIFAC,SHR\_FAC\_N(f,v,i)\*a1faco(v,i)}]

- CESFORM(i)\*SIGMA1PRIM(i)\*[p1faco(f,i) + a1faco(f,i) -p1prim(i)] ;

!Excerpt 16B: household supply and prices of primary factors!

!WAYANG2 factor market modifications!

Variable

(all,i,AGIND)(all,h,HH) x1lndi\_hh(i,h)# Household supply of land, agri.#;

p1cap\_ag # National variable capital rental, agri. #;

p1cap\_nagv # National variable capital rental, non-ag. #;

(all,h,hh) w1cap\_v(h) # Returns to variable capital by household #;

(all,h,hh) w1cap\_f(h) # Returns to fixed capital by household #;

(all,h,hh) x1cap\_vah(h) # variable capital by household, agri. #;

(all,h,hh) x1cap\_vnh(h) # variable capital by household, non-agri. #;

x1cap\_ag # variable capital, agriculture #;

x1cap\_nag # variable capital, non-ag. #;

(all,i,N\_AGIND)x1cap\_f(i) # fixed capital, non-ag. #;

(all,i,N\_AGIND)(all,h,hh)x1cap\_f\_hh(i,h) # fixed capital by h'hold, non-ag. #;

Coefficient

(all,h,hh)(all,f,occ) HINC(h,f) # household factor income #;

(all,i,AGIND)(all,h,HH) LANDS(i,h) #Household land rentals by industry#;

Read

HINC from file MDATA header "HINC";

LANDS from file mdata Header "LAND";

Update

(all,i,AGIND)(all,h,HH) LANDS(i,h) = p1fac("land",i)\*x1lndi\_hh(i,h);

(all,i,AGIND) V1CAPA(i) = p1fac("varcap",i)\*x1fac("varcap",i);

(all,k,KAP)(all,i,N\_AGIND)V1CAPN(k,i)= p1faco(k,i)\*x1faco(k,i);

Equation E\_p1lab\_i # Supply of labour #

(all,o,OCC)sum{h,HH,HINC(h,o)}\* x1lab\_i(o) =

sum{h,HH,HINC(h,o)\*[x1lab\_i\_h(o,h)+f1lab\_i\_x(o)]};

Equation E\_p1lnd # supply of land #

(all,i,AGIND)V1LND(i)\*x1lnd(i) = Sum{h,HH, LANDS(i,h)\*x1lndi\_hh(i,h)};

Equation E\_p1capA # Price of variable + fixed capital, non-agri. #

(all,i,N\_AGIND)V1CAP(i)\*p1cap(i) = sum{k,KAP, V1CAPN(k,i)\*p1faco(k,i)};

Equation E\_p1primA # Effective price term for factor demand equations, ag. #

(all,i,AGIND) V1PRIM(i)\*p1prim(i) =

sum{f,AGRIFAC,V1FAC(f,i)\*[p1fac(f,i) + a1fac(f,i)]};

Equation E\_p1primN # Effective price term for factor demand equations, N\_AG #

(all,i,N\_AGIND) V1PRIM(i)\*p1prim(i) =

sum{f,N\_AGRIFAC,V1FACO(f,i)\*[p1faco(f,i) + a1faco(f,i)]};

!Excerpt 16C: Matching factor p and x to E\_x1fac and E\_x1faco!

!This block deleted if using CES form!

Equation E\_p1facLB # Industry demands for effective labour #

(all,i,AGIND) p1lab\_o(i)=p1fac("unskilled",i);

Equation E\_x1lab\_oA # Effective labour input, agriculture #

(all,i,AGIND) x1lab\_o(i)= x1fac("unskilled",i);

Equation E\_p1facF # Price of fertiliser in agri.#

(all,i,AGIND) p1fac("fert",i) = p1\_s ("PpkPestisida",i);

Equation E\_p1capB # Price of variable capital, agri. #

(all,i,AGIND)p1cap(i) = p1fac("varcap",i);

Equation E\_x1lnd # Industry demands for land #

(all,i,AGIND) x1lnd(i) = x1fac("land",i);

Equation E\_p1facL # Price of land in agri. #

(all,i,AGIND)p1lnd(i) = p1fac("land",i);

Equation E\_p1facK # Equalise price of capital in agri. #

(all,i,AGIND)p1fac("varcap",i)=p1cap\_ag ;

Equation E\_x1lab\_oB # Industry demands for effective labour #

(all,i,N\_AGIND) x1lab\_o(i) = x1faco("labcomp",i);

Equation E\_p1facoLC # Price to each industry of labour composite #

(all,i,N\_AGIND)p1faco("labcomp",i) = p1lab\_o(i) ;

Equation E\_p1facoKN # Price of variable capital in non-ag #

(all,i,N\_AGIND)p1faco("varcap",i)=p1cap\_nagv;

Equation E\_p1facoFC # supply of fixed capital by household #

(all,i,N\_AGIND)x1cap\_f(i) = x1faco("fixcap",i);

!Excerpt 16D: household supply coefficents!

Coefficient

!(all,f,OCC) (all,i,IND)PRIM(f,i) # factor income by industry #; !

(all,h,HH)(all,i,N\_AGIND)FIXEDK(h,i) #Household supplies of fixed capital#;

(all,h,HH) MMA(h) # Household supplies of agri variable capital#;

(all,h,HH) MMN(h)# Household supplies of non-agri variable capital#;

Read

! PRIM from file MDATA header "PRIM";!

FIXEDK from file mdata Header "CAPS";

MMA from file mdata Header "CAPA";

MMN from file mdata Header "CAPN";

Update

!(all,o,OCC)(all,i,N\_AGIND)PRIM(o,i) = x1lab(i,o)\*p1lab(i,o);!

(all,h,hh) (all,o,OCC) HINC(h,o) = x1lab\_i\_h(o,h)\*p1lab\_i(o)\*f1lab\_i\_x(o);

(all,h,HH)(all,i,N\_AGIND)FIXEDK(h,i) = p1faco("fixcap",i)\*x1cap\_f\_hh(i,h);

(all,h,HH) MMA(h) = p1cap\_ag \* x1cap\_vah(h);

(all,h,HH) MMN(h) = p1cap\_nagv \* x1cap\_vnh(h);

Equation E\_p1lab # Equalising of money wages #

(all,i,IND)(all,o,OCC)

p1lab(i,o)= p1lab\_i(o);

!Excerpt 16E: Market clearing of household factors!

Equation E\_x1cap\_f # supply of fixed capital by household #

(all,i,N\_AGIND)sum{h,HH,FIXEDK(h,i)}\*x1cap\_f(i) =

sum{h,HH,FIXEDK(h,i)\*x1cap\_f\_hh(i,h)};

Equation E\_p1cap\_ag # market clearing, variable capital, agriculture #

sum{i,AGIND,V1CAP(i)}\*x1cap\_ag = sum{i,AGIND,V1CAP(i)\*x1cap(i)};

Equation E\_x1cap\_ag # household supply of variable capital, ag.#

sum{h,HH,MMA(h)}\*x1cap\_ag = sum{h,HH,MMA(h)\*x1cap\_vah(h)};

Equation E\_p1cap\_nagv # variable capital, non-ag. #

sum{h,HH,MMN(h)}\*x1cap\_nag = sum{h,HH,MMN(h)\*x1cap\_vnh(h)};

Equation E\_x1cap\_nag # market clearing for variable capital, non-ag. #

sum{i,N\_AGIND,V1CAPN("varcap",i)}\*x1cap\_nag =

sum{i,N\_AGIND,V1CAPN("varcap",i)\*x1faco("varcap",i)};

Equation E\_x1capA # agri. industry capital, variable #

(all,i,AGIND)x1cap(i)=x1fac("varcap",i);

Equation E\_x1capN # non-agri. industry capital, fixed + variable #

(all,i,N\_AGIND)V1CAP(i)\*x1cap(i) = sum{k,KAP, V1CAPN(k,i)\*x1faco(k,i)};

!Summing returns to household factors!

Equation E\_w1cap\_v # Returns to variable capital by household #

(all,h,HH)[MMA(h)+MMN(h)]\*w1cap\_v(h) =

MMA(h)\* [p1cap\_ag + x1cap\_vah(h)] + MMN(h) \* [p1cap\_nagv + x1cap\_vnh(h)];

Equation E\_w1cap\_f # Returns to fixed capital by household #

(all,h,HH)sum{i,N\_AGIND,FIXEDK(h,i)}\*w1cap\_f(h) =

sum{i,N\_AGIND,FIXEDK(h,i)\*[p1faco("fixcap",i) + x1cap\_f\_hh(i,h)]};

! Excerpt 17 of TABLO input file: !

! Import/domestic composition of intermediate demands !

!$ X1\_S(c,i) = CES( All,s,SRC: X1(c,s,i)/A1(c,s,i) ) !

Coefficient (all,c,COM) SIGMA1(c) # Armington elasticities: intermediate #;

Read SIGMA1 from file MDATA header "1ARM";

Equation E\_x1 # Source-specific commodity demands #

(all,c,COM)(all,s,SRC)(all,i,IND)

x1(c,s,i)-a1(c,s,i) = x1\_s(c,i) - SIGMA1(c)\*[p1(c,s,i)+a1(c,s,i) - p1\_s(c,i)];

Equation E\_p1\_s # Effective price of commodity composite #

(all,c,COM)(all,i,IND)

p1\_s(c,i) = sum{s,SRC, S1(c,s,i)\*[p1(c,s,i) + a1(c,s,i)] };

! Excerpt 18 of TABLO input file: !

! Top nest of industry input demands !

!$ X1TOT(i) = MIN( All,c,COM: X1\_S(c,i)/[A1\_S(c,s,i)\*A1TOT(i)], !

!$ X1PRIM(i)/[A1PRIM(i)\*A1TOT(i)], !

!$ X1OCT(i)/[A1OCT(i)\*A1TOT(i)] ) !

Equation E\_x1\_sA # Demands for commodity composites, non-agriculture #

(all,c,COM)(all,i,N\_AGIND) x1\_s(c,i) - [a1\_s(c,i) + a1tot(i)] = x1tot(i);

Equation E\_x1\_sB # Demands for commodity composites, agriculture #

(all,c,NONFERT)(all,i,AGIND) x1\_s(c,i) - [a1\_s(c,i) + a1tot(i)] = x1tot(i);

! demands for fertiliser are no longer Leontief !

Equation E\_x1\_sC # Demands for composite fertiliser inputs, agri. production #

(all,i,AGIND)x1\_s("PpkPestisida",i) = x1fac("fert",i);

!a1\_s("C39fert") is a1fac("C39fert") in agricultural industries!

Equation E\_x1prim # Demands for primary factor composite #

(all,i,IND)x1prim(i) - [a1tot(i) + a1prim(i)] = x1tot(i);

Equation E\_x1oct # Demands for other cost tickets #

(all,i,IND) x1oct(i) - [a1oct(i) + a1tot(i)] = x1tot(i);

Equation E\_p1totA # Zero pure profits in production #

(all,i,N\_AGIND)

V1TOT(i)\*[p1tot(i)-a1tot(i)] =

sum{c,COM, V1PUR\_S(c,i) \*[p1\_s(c,i) + a1\_s(c,i)] }

+ V1PRIM(i) \*[p1prim(i) + a1prim(i)]

+ V1OCT(i) \*[p1oct(i) + a1oct(i)];

Equation E\_p1totB # Zero pure profits in production #

(all,i,AGIND)

V1TOT(i)\*[p1tot(i)-a1tot(i)] =

sum{c,NONFERT, V1PUR\_S(c,i) \*[p1\_s(c,i) + a1\_s(c,i)] }

+ V1PRIM(i) \*[p1prim(i) + a1prim(i)]

+ V1OCT(i) \*[p1oct(i) + a1oct(i)];

! Excerpt 19A of TABLO input file: !

! Output mix of commodities !

Coefficient (all,i,IND) SIGMA1OUT(i) # CET transformation elasticities #;

Read SIGMA1OUT from file MDATA header "SCET";

Equation E\_q1 # Supplies of commodities by industries #

(all,c,COM)(all,i,IND)

q1(c,i) = x1tot(i) + SIGMA1OUT(i)\*[p0com(c) - p1tot(i)];

Coefficient

(all,i,IND) MAKE\_C(i) # All production by industry i #;

(all,c,COM) MAKE\_I(c) # Total production of commodities #;

Formula

(all,i,IND) MAKE\_C(i) = sum{c,COM, MAKE(c,i) };

(all,c,COM) MAKE\_I(c) = sum{i,IND, MAKE(c,i) };

Equation E\_x1tot # Average price received by industries #

(all,i,IND) MAKE\_C(i)\*p1tot(i) = sum{c,COM, MAKE(c,i)\*p0com(c) };

Equation E\_x0com # Total output of commodities #

(all,c,COM) MAKE\_I(c)\*x0com(c) = sum{i,IND, MAKE(c,i)\*q1(c,i) };

! Excerpt 19B of TABLO input file: !

! CET between outputs for local and export markets !

Coefficient

(all, c,COM) EXPSHR(c) # share going to exports #;

(all, c,COM) TAU(c) # 1/elast. of transformation, exportable/locally used #;

Zerodivide Default 0.5;

Formula

(all,c,COM) EXPSHR(c) = V4BAS(c)/SALES(c);

(all,c,COM) TAU(c) = 0.0; ! if zero, p0dom = pe, and CET is nullified !

Zerodivide Off;

Equation E\_x0dom # supply of commodities to export market #

(all,c,COM) TAU(c)\*[x0dom(c) - x4(c)] = p0dom(c) - pe(c);

Equation E\_pe # supply of commodities to domestic market #

(all,c,COM) x0com(c) = [1.0-EXPSHR(c)]\*x0dom(c) + EXPSHR(c)\*x4(c);

Equation E\_p0com # Zero pure profits in transformation #

(all,c,COM) p0com(c) = [1.0-EXPSHR(c)]\*p0dom(c) + EXPSHR(c)\*pe(c);

! Map between vector and matrix forms of basic price variables !

Equation E\_p0dom # Basic price of domestic goods = p0(c,"dom") #

(all,c,COM) p0dom(c) = p0(c,"dom");

Equation E\_p0imp # Basic price of imported goods = p0(c,"imp") #

(all,c,COM) p0imp(c) = p0(c,"imp");

! Excerpt 20 of TABLO input file: !

! Investment demands !

!$ X2\_S(c,i) = CES( All,s,SRC: X2(c,s,i)/A2(c,s,i) ) !

Coefficient (all,c,COM) SIGMA2(c) # Armington elasticities: investment #;

Read SIGMA2 from file MDATA header "2ARM";

Equation E\_x2 # Source-specific commodity demands #

(all,c,COM)(all,s,SRC)(all,i,IND)

x2(c,s,i)-a2(c,s,i) - x2\_s(c,i) = - SIGMA2(c)\*[p2(c,s,i)+a2(c,s,i) - p2\_s(c,i)];

Equation E\_p2\_s # Effective price of commodity composite #

(all,c,COM)(all,i,IND)

p2\_s(c,i) = sum{s,SRC, S2(c,s,i)\*[p2(c,s,i)+a2(c,s,i)] };

! Investment top nest !

!$ X2TOT(i) = MIN( All,c,COM: X2\_S(c,i)/[A2\_S(c,s,i)\*A2TOT(i)] ) !

Equation E\_x2\_s # Demands for commodity composites #

(all,c,COM)(all,i,IND) x2\_s(c,i) - [a2\_s(c,i) + a2tot(i)] = x2tot(i);

Equation E\_p2tot # Zero pure profits in investment #

(all,i,IND) V2TOT(i)\*(p2tot(i) - a2tot(i)) =

sum{c,COM, V2PUR\_S(c,i) \*[p2\_s(c,i)+a2\_s(c,i)] };

! Excerpt 21 of TABLO input file: !

! Import/domestic composition of household demands !

!$ X3\_S(c,i) = CES( All,s,SRC: X3(c,s)/A3(c,s) ) !

Coefficient (all,c,COM) SIGMA3(c) # Armington elasticities: households #;

Read SIGMA3 from file MDATA header "3ARM";

Equation E\_x3 # Source-specific commodity demands #

(all,c,COM)(all,s,SRC)(all,h,HH)

x3(c,s,h)-a3(c,s) = x3\_s(c,h) - SIGMA3(c)\*[ p3(c,s,h)+a3(c,s) - p3\_s(c,h) ];

Equation E\_p3\_s # Effective price of commodity composite #

(all,c,COM)(all,h,HH) p3\_s(c,h) = sum{s,SRC, S3(c,s,h)\*[p3(c,s,h)+a3(c,s)] };

! Excerpt 22 of TABLO input file: !

! Data and formulae for coefficients used in household demand equations !

Coefficient (all,h,HH)FRISCH(h) # Frisch LES 'parameter'= - (total/luxury) #;

Read FRISCH from file MDATA header "P021";

Update (change) (all,h,HH)FRISCH(h) = FRISCH(h)\*[w3tot\_hh(h) - w3lux(h)]/100.0;

Coefficient (all,c,COM)(all,h,HH)

EPS(c,h) # Household expenditure elasticities #;

Read EPS from file MDATA header "XPEL";

Update (change)

(all,c,COM)(all,h,HH) EPS(c,h) =

EPS(c,h)\*[x3lux(c,h)-x3\_s(c,h)+w3tot\_hh(h)-w3lux(h)]/100.0;

Coefficient (all,c,COM)(all,h,HH) S3\_S(c,h) # Household average budget shares #;

Formula (all,c,COM)(all,h,HH) S3\_S(c,h) = V3PUR\_S(c,h)/V3TOT\_HH(h);

Coefficient (all,c,COM)(all,h,HH)B3LUX(c,h)

# Ratio, (supernumerary expenditure/total expenditure), by commodity #;

Formula (all,c,COM)(all,h,HH) B3LUX(c,h) = -EPS(c,h)/FRISCH(h);

Coefficient(all,c,COM)(all,h,HH)S3LUX(c,h) # Marginal household budget shares #;

Formula (all,c,COM)(all,h,HH)S3LUX(c,h) = EPS(c,h)\*S3\_S(c,h);

! Excerpt 23 of TABLO input file: !

! Commodity composition of household demand !

Equation E\_x3sub # Subsistence demand for composite commodities #

(all,c,COM)(all,h,HH) x3sub(c,h) = q(h) + a3sub(c,h);

Equation E\_x3lux # Luxury demand for composite commodities #

(all,c,COM)(all,h,HH) x3lux(c,h) + p3\_s(c,h) = w3lux(h) + a3lux(c,h);

Equation E\_x3\_s # Total household demand for composite commodities #

(all,c,COM)(all,h,HH) x3\_s(c,h) =

B3LUX(c,h)\*x3lux(c,h) + [1-B3LUX(c,h)]\*x3sub(c,h);

Equation E\_utility # Change in utility disregarding taste change terms #

(all,h,HH)utility(h) + q(h) = sum{c,COM, S3LUX(c,h)\*x3lux(c,h) };

Equation E\_a3lux # Default setting for luxury taste shifter #

(all,c,COM)(all,h,HH)a3lux(c,h) = a3sub(c,h) - sum{k,COM,S3LUX(k,h)\*a3sub(k,h)};

Equation E\_a3sub # Default setting for subsistence taste shifter #

(all,c,COM)(all,h,HH)a3sub(c,h) = a3\_s(c,h) - sum{k,COM, S3\_S(k,h)\*a3\_s(k,h) };

! Excerpt 24 of TABLO input file: !

! Export and government demands !

Coefficient (all,c,COM) EXP\_ELAST(c)

# Export demand elasticities: typical value -20.0 #;

Read EXP\_ELAST from file MDATA header "P018";

Equation E\_x4A # export demand functions #

(all,c,COM) x4(c) - f4q(c) = EXP\_ELAST(c)\*[p4(c) - phi - f4p(c)];

Equation E\_x5 # Government demands #

(all,c,COM)(all,s,SRC) x5(c,s) = f5(c,s) + f5tot;

Equation E\_f5tot # Overall government demands shift #

f5tot = x3tot + f5tot2;

! Excerpt 25 of TABLO input file: !

! Margin demands !

Equation E\_x1mar # Margins to producers #

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR) x1mar(c,s,i,m) = x1(c,s,i) + a1mar(c,s,i,m);

Equation E\_x2mar # Margins to capital creators #

(all,c,COM)(all,s,SRC)(all,i,IND)(all,m,MAR) x2mar(c,s,i,m) = x2(c,s,i) + a2mar(c,s,i,m);

Equation E\_x3mar # Margins to households #

(all,c,COM)(all,s,SRC)(all,m,MAR)(all,h,HH) x3mar(c,s,m,h) = x3(c,s,h) + a3mar(c,s,m);

Equation E\_x4mar # Margins to exports #

(all,c,COM)(all,m,MAR) x4mar(c,m) = x4(c) + a4mar(c,m);

Equation E\_x5mar # Margins to government users #

(all,c,COM)(all,s,SRC)(all,m,MAR) x5mar(c,s,m) = x5(c,s) + a5mar(c,s,m);

! Excerpt 26 of TABLO input file: !

! The price system !

Equation E\_p1 # Purchasers prices - producers #

(all,c,COM)(all,s,SRC)(all,i,IND)

[V1PUR(c,s,i)+TINY]\*p1(c,s,i) =

[V1BAS(c,s,i)+V1TAX(c,s,i)]\*[p0(c,s)+ t1(c,s,i)]

+ sum{m,MAR, V1MAR(c,s,i,m)\*[p0dom(m)+a1mar(c,s,i,m)] };

Equation E\_p2 # Purchasers prices - capital creators #

(all,c,COM)(all,s,SRC)(all,i,IND)

[V2PUR(c,s,i)+TINY]\*p2(c,s,i) =

[V2BAS(c,s,i)+V2TAX(c,s,i)]\*[p0(c,s)+ t2(c,s,i)]

+ sum{m,MAR, V2MAR(c,s,i,m)\*[p0dom(m)+a2mar(c,s,i,m)] };

Equation E\_p3 # Purchasers prices - households #

(all,c,COM)(all,s,SRC)(all,h,HH)

[V3PUR(c,s,h)+TINY]\*p3(c,s,h) =

[V3BAS(c,s,h)+V3TAX(c,s,h)]\*[p0(c,s)+ t3(c,s)]

+ sum{m,MAR,V3MAR(c,s,m,h)\*[p0dom(m)+a3mar(c,s,m)] };

Equation E\_p4 # Zero pure profits in exporting #

(all,c,COM)

[V4PUR(c)+TINY]\*p4(c) = [V4BAS(c)+V4TAX(c)]\*[pe(c)+ t4(c)]

+ sum{m,MAR, V4MAR(c,m)\*[p0dom(m)+a4mar(c,m)] };

! note that we refer to export taxes,not subsidies !

Equation E\_p5 # Zero pure profits in distribution of government #

(all,c,COM)(all,s,SRC)

[V5PUR(c,s)+TINY]\*p5(c,s) = [V5BAS(c,s)+V5TAX(c,s)]\*[p0(c,s)+ t5(c,s)]

+ sum{m,MAR, V5MAR(c,s,m)\*[p0dom(m)+a5mar(c,s,m)] };

Equation E\_p0A # Zero pure profits in importing #

(all,c,COM) p0(c,"imp") = pf0cif(c) + phi + t0imp(c);

! Excerpt 27 of TABLO input file: !

! Market clearing equations !

Equation E\_p0B # Demand equals supply for non margin commodities #

(all,n,NONMAR)

DOMSALES(n)\*x0dom(n) =

sum{i,IND, V1BAS(n,"dom",i)\*x1(n,"dom",i)

+ V2BAS(n,"dom",i)\*x2(n,"dom",i) }

+ sum{h,HH, V3BAS(n,"dom",h)\*x3(n,"dom",h)}

+ V5BAS(n,"dom")\*x5(n,"dom") ! note exports omitted !

+ 100\*LEVP0(n,"dom")\*delx6(n,"dom");

Equation E\_p0C # Demand equals supply for margin commodities #

(all,m,MAR)

DOMSALES(m)\*x0dom(m) = ! basic part first !

sum{i,IND, V1BAS(m,"dom",i)\*x1(m,"dom",i)

+ V2BAS(m,"dom",i)\*x2(m,"dom",i) }

+ sum{h,HH, V3BAS(m,"dom",h)\*x3(m,"dom",h)}

+ V5BAS(m,"dom")\*x5(m,"dom") ! note exports omitted !

+ 100\*LEVP0(m,"dom")\*delx6(m,"dom") ! now margin part !

+ sum{c,COM, V4MAR(c,m)\*x4mar(c,m) ! note nesting of sum parentheses !

+ sum{s,SRC,sum(h,HH, V3MAR(c,s,m,h)\*x3mar(c,s,m,h))

+ V5MAR(c,s,m)\*x5mar(c,s,m)

+ sum{i,IND, V1MAR(c,s,i,m)\*x1mar(c,s,i,m)

+ V2MAR(c,s,i,m)\*x2mar(c,s,i,m) }}};

Equation E\_x0imp # Import volumes #

(all,c,COM)

[TINY + V0IMP(c)]\*x0imp(c) =

sum{i,IND, V1BAS(c,"imp",i)\*x1(c,"imp",i)

+ V2BAS(c,"imp",i)\*x2(c,"imp",i) }

+ sum{h,HH, V3BAS(c,"imp",h)\*x3(c,"imp",h)}

+ V5BAS(c,"imp")\*x5(c,"imp")

+ 100\*LEVP0(c,"imp")\*delx6(c,"imp");

Equation E\_x1lab\_i # Demand equals supply for labour of each skill #

(all,o,OCC) V1LAB\_I(o)\*x1lab\_i(o) = sum{i,IND, V1LAB(i,o)\*x1lab(i,o) };

! Excerpt 28 of TABLO input file: !

! Tax rate equations !

Equation

E\_t1 # Power of tax on sales to intermediate #

(all,c,COM)(all,s,SRC)(all,i,IND) t1(c,s,i) = f0tax\_s(c) + f1tax\_csi;

E\_t2 # Power of tax on sales to investment #

(all,c,COM)(all,s,SRC)(all,i,IND) t2(c,s,i) = f0tax\_s(c) + f2tax\_csi;

E\_t3 # Power of tax on sales to households #

(all,c,COM)(all,s,SRC) t3(c,s) = f0tax\_s(c) + f3tax\_cs;

E\_t4A # Power of tax on sales to traditional exports #

(all,c,COM) t4(c) = f4tax\_x(c) + f4tax\_c;

E\_t5 # Power of tax on sales to government #

(all,c,COM)(all,s,SRC) t5(c,s) = f0tax\_s(c) + f5tax\_cs;

! Excerpt 29 of TABLO input file: !

! Indirect tax revenue !

Equation

E\_w1tax\_csi # Revenue from indirect taxes on flows to intermediate #

[TINY + V1TAX\_CSI]\*w1tax\_csi = sum{c,COM, sum{s,SRC, sum{i,IND,

V1TAX(c,s,i)\*[p0(c,s)+x1(c,s,i)]+[V1TAX(c,s,i)+V1BAS(c,s,i)]\*t1(c,s,i) }}};

E\_w2tax\_csi # Revenue from indirect taxes on flows to investment #

[TINY + V2TAX\_CSI]\*w2tax\_csi = sum{c,COM, sum{s,SRC, sum{i,IND,

V2TAX(c,s,i)\*[p0(c,s)+x2(c,s,i)]+[V2TAX(c,s,i)+V2BAS(c,s,i)]\*t2(c,s,i) }}};

E\_w3tax\_cs # Revenue from indirect taxes on flows to households #

[TINY + V3TAX\_CS]\*w3tax\_cs = sum{c,COM, sum{s,SRC,sum{h,HH,

V3TAX(c,s,h)\*[p0(c,s)+ x3(c,s,h)] + [V3TAX(c,s,h)+V3BAS(c,s,h)]\*t3(c,s)}}};

E\_w4tax\_c # Revenue from indirect taxes on exports #

[TINY + V4TAX\_C]\*w4tax\_c = sum{c,COM,

V4TAX(c)\*[pe(c) + x4(c)] + [V4TAX(c)+ V4BAS(c)]\*t4(c) };

E\_w5tax\_cs # Revenue from indirect taxes on flows to government #

[TINY + V5TAX\_CS]\*w5tax\_cs = sum{c,COM, sum{s,SRC,

V5TAX(c,s)\*[p0(c,s)+ x5(c,s)] + [V5TAX(c,s)+V5BAS(c,s)]\*t5(c,s) }};

E\_w0tar\_c # Tariff revenue #

[TINY+V0TAR\_C]\*w0tar\_c = sum{c,COM,

V0TAR(c)\*[pf0cif(c) + phi + x0imp(c)] + V0IMP(c)\*t0imp(c) };

! Excerpt 30 of TABLO input file: !

! Factor incomes and GDP !

Equation

E\_w1lnd\_i # Aggregate payments to land #

V1LND\_i\*w1lnd\_i = sum{i,AGIND, V1LND(i)\*[x1lnd(i)+p1lnd(i)] };

E\_w1lab\_io # Aggregate payments to labour #

V1LAB\_IO\*w1lab\_io = sum{i,IND, sum{o,OCC, V1LAB(i,o)\*[x1lab(i,o)+p1lab(i,o)]}};

E\_w1cap\_i # Aggregate payments to capital #

V1CAP\_I\*w1cap\_i = sum{i,IND, V1CAP(i)\*[x1cap(i)+p1cap(i)] };

E\_w1oct\_i # Aggregate other cost ticket payments #

V1OCT\_I\*w1oct\_i = sum{i,IND, V1OCT(i)\*[x1oct(i)+p1oct(i)] };

E\_w0tax\_csi # Aggregate value of indirect taxes #

V0TAX\_CSI\*w0tax\_csi = V1TAX\_CSI\*w1tax\_csi + V2TAX\_CSI\*w2tax\_csi

+ V3TAX\_CS\*w3tax\_cs + V4TAX\_C\*w4tax\_c + V5TAX\_CS\*w5tax\_cs + V0TAR\_C\*w0tar\_c;

E\_w0gdpinc # Aggregate nominal GDP from income side #

V0GDPINC\*w0gdpinc = V1LND\_I\*w1lnd\_i + V1CAP\_I\*w1cap\_i + V1LAB\_IO\*w1lab\_io

+ V1OCT\_I\*w1oct\_i + V0TAX\_CSI\*w0tax\_csi;

! Excerpt 31 of TABLO input file: !

! GDP expenditure aggregates !

E\_x2tot\_i # Total real investment #

V2TOT\_I\*x2tot\_i = sum{i,IND, V2TOT(i)\*x2tot(i) };

E\_p2tot\_i # Investment price index #

V2TOT\_I\*p2tot\_i = sum{i,IND, V2TOT(i)\*p2tot(i) };

E\_w2tot\_i # Total nominal investment #

w2tot\_i = x2tot\_i + p2tot\_i;

E\_x3tot\_hh # Real consumption #

(all,h,HH)V3TOT\_HH(h)\*x3tot\_hh(h)=sum{c,COM,sum{s,SRC,V3PUR(c,s,h)\*x3(c,s,h)}};

E\_p3tot\_hh # Household price index #

(all,h,HH)V3TOT\_HH(h)\*p3tot\_hh(h)=sum{c,COM,sum{s,SRC,V3PUR(c,s,h)\*p3(c,s,h)}};

E\_w3tot\_hh # Household budget constraint #

(all,h,HH)w3tot\_hh(h) = x3tot\_hh(h) + p3tot\_hh(h);

E\_x3tot # Real consumption #

V3TOT\*x3tot = sum{h,HH,V3TOT\_HH(h)\*x3tot\_hh(h)};

E\_p3tot # Consumer price index #

V3TOT\*p3tot = sum{h,HH,V3TOT\_HH(h)\*p3tot\_hh(h)};

E\_w3tot # Household budget constraint #

w3tot = x3tot + p3tot;

E\_x4tot # Export volume index #

V4TOT\*x4tot = sum{c,COM, V4PUR(c)\*x4(c) };

E\_p4tot # Exports price index, rupiah #

V4TOT\*p4tot = sum{c,COM, V4PUR(c)\*p4(c) };

E\_w4tot # rupiah border value of exports #

w4tot = x4tot + p4tot;

E\_x5tot # Aggregate real government demands #

V5TOT\*x5tot = sum{c,COM, sum{s,SRC, [TINY+V5PUR(c,s)]\*x5(c,s) }};

E\_p5tot # Government price index #

V5TOT\*p5tot = sum{c,COM, sum{s,SRC, V5PUR(c,s)\*p5(c,s) }};

E\_w5tot # Aggregate nominal value of government demands #

w5tot = x5tot + p5tot;

E\_x6tot # Inventories volume index #

V6TOT\*x6tot = 100\*sum{c,COM, sum{s,SRC, LEVP0(c,s)\*delx6(c,s) }};

E\_p6tot # Inventories price index #

[TINY+V6TOT]\*p6tot = sum{c,COM, sum{s,SRC, V6BAS(c,s)\*p0(c,s) }};

E\_w6tot # Aggregate nominal value of inventories #

w6tot = x6tot + p6tot;

E\_x0cif\_c # Import volume index, C.I.F. weights #

V0CIF\_C\*x0cif\_c = sum{c,COM, V0CIF(c)\*x0imp(c) };

E\_p0cif\_c # Imports price index, rupiah C.I.F. #

V0CIF\_C\*p0cif\_c = sum{c,COM, V0CIF(c)\*[phi+pf0cif(c)] };

E\_w0cif\_c # Value of imports, rupiah C.I.F. #

w0cif\_c = x0cif\_c + p0cif\_c;

E\_x0gdpexp # Real GDP, expenditure side #

V0GDPEXP\*x0gdpexp = V3TOT\*x3tot + V2TOT\_I\*x2tot\_i + V5TOT\*x5tot

+ V6TOT\*x6tot + V4TOT\*x4tot - V0CIF\_C\*x0cif\_c;

E\_p0gdpexp # Price index for GDP, expenditure side #

V0GDPEXP\*p0gdpexp = V3TOT\*p3tot + V2TOT\_I\*p2tot\_i + V5TOT\*p5tot

+ V6TOT\*p6tot + V4TOT\*p4tot - V0CIF\_C\*p0cif\_c;

E\_w0gdpexp # Nominal GDP from expenditure side #

w0gdpexp = x0gdpexp + p0gdpexp;

! Excerpt 32 of TABLO input file: !

! Trade balance and other aggregates !

Equation

E\_delB # %(Balance of trade)/GDP #

V0GDPEXP\*delB = V4TOT\*w4tot - V0CIF\_C\*w0cif\_c

-(V4TOT-V0CIF\_C)\*w0gdpexp;

E\_x0imp\_c # Import volume index, duty paid weights #

V0IMP\_C\*x0imp\_c = sum{c,COM, V0IMP(c)\*x0imp(c) };

E\_p0imp\_c # Duty paid imports price index #

V0IMP\_C\*p0imp\_c = sum{c,COM, V0IMP(c)\*p0(c,"imp") };

E\_w0imp\_c # Value of imports (duty paid) #

w0imp\_c = x0imp\_c + p0imp\_c;

E\_x1cap\_i # Aggregate usage of capital,rental weights #

V1CAP\_I\*x1cap\_i = sum{i,IND, V1CAP(i)\*x1cap(i) };

E\_p1cap\_i # Average capital rental #

V1CAP\_I\*p1cap\_i = sum{i,IND, V1CAP(i)\*p1cap(i) };

Equation E\_employ # Employment by industry #

(all,i,IND) V1LAB\_O(i)\*employ(i) = sum{o,OCC, V1LAB(i,o)\*x1lab(i,o) };

E\_p1lab\_io # Average nominal wage #

V1LAB\_IO\*p1lab\_io = sum{i,IND, sum{o,OCC, V1LAB(i,o)\*p1lab(i,o) }};

E\_realwage # Average real wage #

realwage = p1lab\_io - p3tot;

E\_x1prim\_i # Aggregate output: value-added weights #

V1PRIM\_I\*x1prim\_i = sum{i,IND, V1PRIM(i)\*x1tot(i) };

E\_p0toft # Terms of trade #

p0toft = p4tot - p0cif\_c;

E\_p0realdev # Real devaluation #

p0realdev = p0cif\_c - p0gdpexp;

! Excerpt 33 of TABLO input file: !

! Investment equations !

! Follows Section 19 of DPSV - warts and all. In particular, the

ratios Q and G are treated as parameters, just as in the original

ORANI implementation. Attempts to improve the theory by updating

these parameters have been found to occasionally lead to perversely

signed coefficients !

Variable

(all,i,IND) finv(i) # Investment shifter #;

(all,i,IND) r1cap(i) # Current rates of return on capital #;

omega # Economy-wide "rate of return" #;

Equation E\_r1cap # Definition of rates of return to capital #

(all,i,IND) r1cap(i) = 2.0\*(p1cap(i) - p2tot(i));

! Note: above equation comes from DPSV equation 19.7. The value 2.0

corresponds to the DPSV ratio Q (= ratio, gross to net rate of

return) and is a typical value of this ratio. !

Equation E\_x2totA # Investment rule #

(all,i,ENDOGINV)

x2tot(i) - x1cap(i) = finv(i) + 0.33\*[r1cap(i) - omega];

! Note: above equation comes from substituting together DPSV

equations 19.8-9. The value 0.33 corresponds to the DPSV ratio

[1/G.Beta] and is a typical value of this ratio. !

Equation E\_x2totB # Investment in exogenous industries #

(all,i,EXOGINV) x2tot(i) = x2tot\_i + finv(i);

! Excerpt 34 of TABLO input file: !

! Indexing and other equations !

Equation E\_p1oct # Indexing of prices of "other cost" tickets #

(all,i,IND) p1oct(i) = p3tot + f1oct(i); ! assumes full indexation !

E\_delx6 # possible rule for stocks #

(all,c,COM)(all,s,SRC) 100\*LEVP0(c,s)\*delx6(c,s)=V6BAS(c,s)\*x0com(c)+fx6(c,s);

! Excerpt 35 of TABLO input file: !

! Decomposition of Fan !

Set FANCAT # parts of Fan decomposition #

(LocalMarket, ImportShare, Export, Total);

Variable

(all,c,COM) x0loc(c) # real percent change in LOCSALES (dom+imp) #;

(change)(all,c,COM)(all,f,FANCAT) fandecomp(c,f) # Fan decomposition #;

Coefficient

(all,c,COM) LOCSALES(c) # Total local sales of dom + imp commodity c #;

(all,c,COM) INITSALES(c) # Initial volume of SALES at final prices #;

Formula

(all,c,COM) LOCSALES(c) = DOMSALES(c) + V0IMP(c);

(initial) (all,c,COM) INITSALES(c) = SALES(c);

Update

(all,c,COM) INITSALES(c) = p0com(c);

Equation E\_x0loc # %growth in local market #

(all,c,COM) LOCSALES(c)\*x0loc(c) =

DOMSALES(c)\*x0dom(c) + V0IMP(c)\*x0imp(c);

Equation E\_fandecompA # growth in local market effect #

(all,c,COM) INITSALES(c)\*fandecomp(c,"LocalMarket") = DOMSALES(c)\*x0loc(c);

! The local market effect is the % change in output that would have occurred

if local sales of the domestic product had followed dom+imp sales (x0loc) !

Equation E\_fandecompB # export effect #

(all,c,COM) INITSALES(c)\*fandecomp(c,"Export") = V4BAS(c)\*x4(c);

Equation E\_fandecompC # import leakage effect - via residual #

(all,c,COM) fandecomp(c,"Total") =

fandecomp(c,"LocalMarket") + fandecomp(c,"ImportShare") + fandecomp(c,"Export");

Equation E\_fandecompD # Fan total = x0com #

(all,c,COM) INITSALES(c)\*fandecomp(c,"Total") = SALES(c)\*x0com(c);

! Excerpt 44 of TABLO input file: !

! Fiscal extension !

Set TYPE (expend, recp);! expend=govt. payments, recp=govt. receipts !

Variable

(all,h,HH)(all,t,TYPE)fgov\_h(h,t) # Shift in transfers: govt. -- households #;

(all,t,TYPE) fgov\_f(t) # Shift in transfers: govt. -- foreign #;

(all,h,HH)(all,t,TYPE)gov\_h(h,t) # Transfers: govt. -- households #;

(all,t,TYPE) gov\_f(t) # Transfers: govt. -- foreign #;

(all,h,HH) w0hhtax(h) # % change in personal income tax #;

(all,h,HH)w0hhinc(h) #Aggregate nominal take-home income earned by households #;

(change) delbudget # Rupiah change in budget balance G-T #;

w0govt\_t # Aggregate government revenue#;

w0govt\_g # Aggregate government expenditure#;

f1inc\_tax # Overall income tax shifter #;

Coefficient

GOVTREV # Total government revenue #;

GOVTEXP # Nominal total current and capital government expenditure #;

(all,i,EXOGINV)V2TOT\_G(i) # Total govt. funding of capital created for i #;

(all,t,TYPE)TRANSFER\_F(t) # Government transfers: payments/receipts foreign#;

(all,h,HH)(all,t,TYPE)TRANSFER\_H(h,t) # Govt transfers to and from h'holds#;

(all,h,HH)V0HHTAX(h) # Personal income tax on all household factors #;

(all,h,HH)V0HHINC(h) # Income earned by households #;

Read

V0HHTAX from file MDATA header "PINC";

TRANSFER\_F from file MDATA header "TRAN";

TRANSFER\_H from file MDATA header "GOHH";

Update (all,t,TYPE) TRANSFER\_F(t) = gov\_f(t);

(all,h,HH)(all,t,TYPE)TRANSFER\_H(h,t) = gov\_h(h,t);

(all,h,HH) V0HHTAX(h) = w0hhtax(h);

Formula

(all,i,EXOGINV)V2TOT\_G(i) = sum{c,COM, V2PUR\_S(c,i) }\*0.3;

!allocation of public investment!

GOVTREV = V0TAX\_CSI + sum{h,HH,V0HHTAX(h)} +

TRANSFER\_F("recp") +sum{h,HH,TRANSFER\_H(h,"recp")};

GOVTEXP = V5TOT + Sum{i,EXOGINV, V2TOT\_G(i)} +

TRANSFER\_F("expend") +sum{h,HH,TRANSFER\_H(h,"expend")};

Equation E\_w3lux # consumption function #

(All,h,HH)

w3tot\_hh(h) = f3tot + f3tot\_h(h) + w0hhinc(h);

Equation E\_w0hhtax #Aggregate nominal income tax paid by households #

(all,h,HH)w0hhtax(h) = w0hhinc(h) + f1inc\_tax;

!Equation E\_w0hhtax constrains any exogenous shifts in the income tax rate to

being equal across all household factors of production. Note that take-home

household income is used in the consumption function.!

Equation E\_gov\_f # Government transfers to and from foreigners #

(all,t,TYPE)gov\_f(t) = p3tot + fgov\_f(t);

Equation E\_gov\_h # Government transfers to and from households #

(all,h,HH)(all,t,TYPE)gov\_h(h,t) = p3tot + fgov\_h(h,t);

Formula (all,h,HH)V0HHINC(h) =

sum{i,AGIND,LANDS(i,h)} + sum{o,OCC,HINC(h,o)} +

MMA(h)+MMN(h) + sum{i,N\_AGIND,FIXEDK(h,i)}

+ TRANSFER\_H(h,"expend") - TRANSFER\_H(h,"recp")

- V0HHTAX(h);

Equation E\_w0hhinc #Aggregate nominal take-home income earned by households #

(all,h,HH)V0HHINC(h)\*w0hhinc(h)=

sum{i,AGIND,LANDS(i,h)\*[p1lnd(i) + x1lndi\_hh(i,h)]} +

sum{o,OCC,HINC(h,o)\*[x1lab\_i\_h(o,h) + p1lab\_i(o) + f1lab\_i\_x(o)]} +

[MMA(h)+MMN(h)]\*w1cap\_v(h) + sum{i,N\_AGIND,FIXEDK(h,i)}\*w1cap\_f(h)

+ TRANSFER\_H(h,"expend")\*gov\_h(h,"expend")

- TRANSFER\_H(h,"recp")\*gov\_h(h,"recp")

- V0HHTAX(h)\*w0hhtax(h);

Equation E\_w0govt\_t # Aggregate government revenue #

GOVTREV\*w0govt\_t = V0TAX\_CSI\*w0tax\_csi + sum{h,HH,V0HHTAX(h)\*w0hhtax(h)}

+ TRANSFER\_F("recp")\*gov\_f("recp") +

sum{h,HH,TRANSFER\_H(h,"recp")\*gov\_h(h,"recp")};

Equation E\_w0govt\_g # Aggregate government expenditure #

GOVTEXP\*w0govt\_g = V5TOT\*w5tot

+ Sum{i,EXOGINV, V2TOT\_G(i)\*[x2tot(i) + p2tot(i)]}

+ TRANSFER\_F("expend")\*gov\_f("expend")

+ sum{h,HH,TRANSFER\_H(h,"expend")\*gov\_h(h,"expend")};

Equation E\_delbudget # Change in budget balance G-T # !increased deficit >0!

100\*delbudget = GOVTEXP\*w0govt\_g - GOVTREV\*w0govt\_t ;

! Excerpt 45 of TABLO input file: !

! Data for Checking Identities !

File (new) SUMMARY # Summary and checking data #;

Coefficient ! coefficients for checking !

(all,i,IND) PURE\_PROFITS(i) # COSTS-MAKE\_C : should be zero #;

(all,c,COM) LOST\_GOODS(c) # SALES-MAKE\_I : should be zero #;

(all,h,HH) EPSTOT(h) # Average Engel elasticity: should = 1 #;

Formula

(all,i,IND) PURE\_PROFITS(i) = V1TOT(i) - MAKE\_C(i);

(all,c,COM) LOST\_GOODS(c) = SALES(c) - MAKE\_I(c);

(all,h,HH) EPSTOT(h) = sum{c,COM, S3\_S(c,h)\*EPS(c,h)};

Write

PURE\_PROFITS to file SUMMARY header "PURE" longname "COSTS-MAKE\_C: should = 0";

LOST\_GOODS to file SUMMARY header "LOST" longname "SALES-MAKE\_I: should = 0";

EPSTOT to file SUMMARY header "ETOT" longname "Average Engel elast: should = 1";

! Excerpt 46 of TABLO input file: !

! Components of GDP from income and expenditure sides !

Set EXPMAC # Expenditure Aggregates #

(Consumption, Investment, Government, Stocks, Exports, Imports);

Coefficient (all,e,EXPMAC) EXPGDP(e) # Expenditure Aggregates #;

Formula

EXPGDP("Consumption") = V3TOT;

EXPGDP("Investment") = V2TOT\_I;

EXPGDP("Government") = V5TOT;

EXPGDP("Stocks") = V6TOT;

EXPGDP("Exports") = V4TOT;

EXPGDP("Imports") = -V0CIF\_C;

Write EXPGDP to file SUMMARY header "EMAC" longname "Expenditure Aggregates";

Set INCMAC # Income Aggregates # (Land, Labour, Capital, OCT, IndTaxes);

Coefficient (all,i,INCMAC) INCGDP(i) # Income Aggregates #;

Formula

INCGDP("Land") = V1LND\_I;

INCGDP("Labour") = V1LAB\_IO;

INCGDP("Capital") = V1CAP\_I;

INCGDP("OCT") = V1OCT\_I;

INCGDP("IndTaxes") = V0TAX\_CSI;

Write INCGDP to file SUMMARY header "IMAC" longname "Income Aggregates";

Set TAXMAC # Tax Aggregates #

(Intermediate,Investment,Consumption,Exports,Government,Tariff);

Coefficient (all,t,TAXMAC) TAX(t) # Tax Aggregates #;

Formula

TAX("Intermediate") = V1TAX\_CSI;

TAX("Investment") = V2TAX\_CSI;

TAX("Consumption") = V3TAX\_CS;

TAX("Exports") = V4TAX\_C;

TAX("Government") = V5TAX\_CS;

TAX("Tariff") = V0TAR\_C;

Write TAX to file SUMMARY header "TMAC" longname "Tax Aggregates";

! Excerpt 47 of TABLO input file: !

! Matrix of Industry Costs !

Set COSTCAT # Cost Categories #

(IntDom, IntImp, margin, IndTax, Lab, Cap, Lnd, ProdTax); ! co !

Coefficient (all,i,IND)(all,co,COSTCAT) COSTMAT(i,co);

Formula

(all,i,IND) COSTMAT(i,"IntDom") = sum{c,COM, V1BAS(c,"dom",i)};

(all,i,IND) COSTMAT(i,"IntImp") = sum{c,COM, V1BAS(c,"imp",i)};

(all,i,IND) COSTMAT(i,"margin") =

sum{c,COM, sum{s,SRC, sum{m,MAR, V1MAR(c,s,i,m)}}};

(all,i,IND) COSTMAT(i,"IndTax") = sum{c,COM, sum{s,SRC, V1TAX(c,s,i)}};

(all,i,IND) COSTMAT(i,"Lab") =V1LAB\_O(i);

(all,i,IND) COSTMAT(i,"Cap") =V1CAP(i);

(all,i,IND) COSTMAT(i,"Lnd") =V1LND(i);

(all,i,IND) COSTMAT(i,"ProdTax") =V1OCT(i);

Write COSTMAT to file SUMMARY header "CSTM" longname "Cost Matrix";

Formula (all,i,IND)(all,co,COSTCAT) ! convert to % shares and re-write !

COSTMAT(i,co)= 100\*COSTMAT(i,co)/(TINY+V1TOT(i));

Write COSTMAT to file SUMMARY header "COSH" longname "Cost Share Matrix";

! Excerpt 48 of TABLO input file: !

! Matrix of domestic commodity sales with total imports !

Set ! Subscript !

SALECAT # SALE Categories #

(Interm, Invest, HouseH, Export, GovGE, Stocks,margins, Total, Imports);

Coefficient (all,c,COM)(all,sa,SALECAT) SALEMAT(c,sa);

Formula

(all,c,COM) SALEMAT(c,"Interm") = sum{i,IND, V1BAS(c,"dom",i)};

(all,c,COM) SALEMAT(c,"Invest") = sum{i,IND, V2BAS(c,"dom",i)};

(all,c,COM) SALEMAT(c,"HouseH") = sum{h,HH,V3BAS(c,"dom",h)};

(all,c,COM) SALEMAT(c,"Export") = V4BAS(c);

(all,c,COM) SALEMAT(c,"GovGE") = V5BAS(c,"dom");

(all,c,COM) SALEMAT(c,"Stocks") = V6BAS(c,"dom");

(all,c,COM) SALEMAT(c,"margins") = MARSALES(c);

(all,c,COM) SALEMAT(c,"Total") = SALES(c);

(all,c,COM) SALEMAT(c,"Imports") = V0IMP(c);

write SALEMAT to file SUMMARY header "SLSM" longname

"Matrix of domestic commodity sales with total imports";

Formula

(all,c,COM)(all,sa,SALECAT) SALEMAT(c,sa) = 100\*SALEMAT(c,sa)/[TINY+SALES(c)];

(all,c,COM) SALEMAT(c,"Imports")= 100\*V0IMP(c)/[TINY+DOMSALES(c)+V0IMP(c)];

Write SALEMAT to file SUMMARY header "SLSH" longname

"market shares for domestic goods with total import share";

! Excerpt 49 of TABLO input file: !

! Weight Vectors for use in aggregation and other calculations !

Write

V1TOT to file SUMMARY header "1TOT" longname "Industry Output";

V2TOT to file SUMMARY header "2TOT" longname "Investment by Industry";

V1PUR\_SI to file SUMMARY header "1PUR" longname "Interm.Usage by com at PP";

V2PUR\_SI to file SUMMARY header "2PUR" longname "Invest.Usage by com at PP";

V3PUR\_S to file SUMMARY header "3PUR" longname "Consumption at Purch.Prices";

V4PUR to file SUMMARY header "4PUR" longname "Exports at Purchasers Prices";

V1LAB\_O to file SUMMARY header "LAB1" longname "Industry Wages";

V1CAP to file SUMMARY header "1CAP" longname "Capital Rentals";

V1PRIM to file SUMMARY header "VLAD" longname "Industry Factor Cost";

! Excerpt 50 of TABLO input file: !

Set

SALECAT2 # SALE Categories # (Interm, Invest, HouseH, Export, GovGE, Stocks);

FLOWTYPE # type of flow # (Basic, margin, Tax);

Coefficient

(all,c,COM)(all,f,FLOWTYPE)(all,s,SRC)(all,sa,SALECAT2) SALEMAT2(c,f,s,sa)

# Basic, margin and tax components of purchasers' values #;

Formula

(all,c,COM)(all,f,FLOWTYPE)(all,s,SRC)(all,sa,SALECAT2) SALEMAT2(c,f,s,sa)=0;

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Basic",s,"Interm") = sum{i,IND,V1BAS(c,s,i)};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Tax" ,s,"Interm") = sum{i,IND,V1TAX(c,s,i)};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"margin",s,"Interm") =

sum{i,IND, sum{m,MAR, V1MAR(c,s,i,m) }};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Basic",s,"Invest") = sum{i,IND,V2BAS(c,s,i)};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Tax" ,s,"Invest") = sum{i,IND,V2TAX(c,s,i)};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"margin",s,"Invest") =

sum{i,IND, sum{m,MAR, V2MAR(c,s,i,m) }};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Basic",s,"HouseH") = sum{h,HH,V3BAS(c,s,h)};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Tax" ,s,"HouseH") = sum{h,HH,V3TAX(c,s,h)};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"margin",s,"HouseH")=

sum{m,MAR,sum(h,HH,V3MAR(c,s,m,h))};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Basic",s,"GovGE") = V5BAS(c,s);

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Tax" ,s,"GovGE") = V5TAX(c,s);

(all,c,COM)(all,s,SRC) SALEMAT2(c,"margin",s,"GovGE")= sum{m,MAR,V5MAR(c,s,m)};

(all,c,COM) SALEMAT2(c,"Basic","dom","Export") = V4BAS(c);

(all,c,COM) SALEMAT2(c,"Tax" ,"dom","Export") = V4TAX(c);

(all,c,COM) SALEMAT2(c,"margin","dom","Export")= sum{m,MAR,V4MAR(c,m)};

(all,c,COM)(all,s,SRC) SALEMAT2(c,"Basic",s,"Stocks") = V6BAS(c,s);

write SALEMAT2 to file SUMMARY header "MKUP" longname

"Basic, margin and tax components of purchasers' values";

Write GOVTREV to file SUMMARY header "TGOV";

GOVTEXP to file SUMMARY header "GGOV";

! end of file !

Lampiran 2. Input *file* c*losure* jangka pendek dan jangka panjang

! Closure Short-Run ! ! "!\*!" indicates difference from longrun

Exogenous q ; !HH! Number of households

Exogenous f5 ; !COM\*SRC! Government demand shift

Exogenous f4p ; !COM! Price (upward) shift in export demand schedule

Exogenous f4q ; !COM! Quantity (right) shift in export demands

Exogenous delx6 ; !COM\*SRC! Inventories demands !\*!

Exogenous phi ; !1! Exchange rate, rupiah/$world

Exogenous a3\_s ; !COM\*HH! Taste change, hhold imp/dom composite

Exogenous finv ; !IND! Investment shifter

Exogenous a1fac ; !AGRIFAC\*AGIND! Primary factor tech. change, agri.

Exogenous a1tot ; !IND! All input augmenting technical change

Exogenous a2tot ; !IND! Neutral technical change - investment

Exogenous f1oct ; !IND! Shift in price of "other cost" tickets

Exogenous f3tot ; !1! Ratio, consumption /income

Exogenous x2tot\_i ; !1! Aggregate real investment expenditure !\*!

Exogenous t0imp ; !COM! Power of tariff

Exogenous a1faco ; !N\_AGRIFAC\*N\_AGIND! Prim. factor tech. change, other

Exogenous a1prim ; !IND! All factor augmenting technical change

Exogenous a1prim ; ! IND All factor augmenting technical change

Exogenous x5tot ; !1! Aggregate real government demands !\*!

Exogenous fgov\_f ; !TYPE! Shift in transfers: govt. -- foreign

Exogenous fgov\_h ; !HH\*TYPE! Shift in transfers: govt. -- households

Exogenous pf0cif ; !COM! C.I.F. foreign currency import prices

Exogenous f0tax\_s ; !COM! General sales tax shifter

Exogenous f4tax\_x ; ! COM General sales tax export

Exogenous f3tot\_h ; !HH! Ratio, consumption/income by hh

Exogenous f3tax\_cs ; !1! Uniform % change in powers taxes household usage

Exogenous f5tax\_cs ; !1! Uniform % change in powers taxes government usage

Exogenous f1inc\_tax ; !1! Overall income tax shifter

Exogenous realwage ; !OCC! Average nominal wage !\*!

Exogenous x1cap\_i; !1! Agregat Capital Stock !\*!

Exogenous f1tax\_csi ; !1! uniform % change powers of taxes intermediate usage

Exogenous f2tax\_csi ; !1! Uniform % change in powers of taxes on investment

Exogenous x1cap\_vah ; !HH! variable capital by household, agri.

Exogenous x1cap\_vnh ; !HH! variable capital by household, non-agri.

Exogenous x1lab\_i\_h ; !OCC\*HH! Household labour supply

Exogenous x1lndi\_hh ; !AGIND\*HH! Household supply of land, agri.

Exogenous f4tax\_c ; !1! Unif % change in powers of taxes on exports

Exogenous x1cap\_f\_hh ; !N\_AGIND\*HH! fixed capital by hhold, non-ag.

Rest endogenous;

cpu=yes ; ! (Optional) Reports CPU times for various stages

|  |  |  |
| --- | --- | --- |
| Closure | SR | LR |
| Swap | delx6 | fx6 |
| x2tot\_i | omega |
| x1cap\_i | delB |
| x5tot | f5tot2 |
| Realwage | p1lab\_io |

Lampiran 3. Komponen data dasar 35 sektor

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| No. | Header | Type | Dimension | Coeff | Total | Name |
| 1. | 0TAR | RE | COM | V0TAR | 22.766,1 | Tariff Revenue |
| 2. | 1ARM | RE | COM | SIGMA1 | 103,52 | Intermediate Armington |
| 3. | 1CAG | RE | AGIND | V1CAPA | 51.012,33 | Capital Rent |
| 4. | 1CAP | RE | KAP\*N\_AGRI | V1CAPN | 2.963.754 | V1CAPN(RNANL:NAI) |
| 5. | 1LND | RE | IND | V1LND | 573.372,6 | Land |
| 6. | 1OCT | RE | IND | V1OCT | -199.702 | Other Cost |
| 7. | CAPA | RE | HH | MMAN | 51.012,33 | MMAN (HH) |
| 8. | CAPN | RE | HH | MMNN | 856.197,2 | Mobile cap owned by HH non AGR |
| 9. | CAPS | RE | HH\*N\_AGRI | FIXEDK | 2.107.557 | Fix capital owned by HH non AGR |
| 10. | SLAB | RE | IND | SIGMA1LAB | 14,12 | Labour Sigma |
| 11. | P028 | RE | IND | SIGMA1PRIM | 17,5 | Primary Factor Sigma |
| 12. | 2ARM | RE | COM | SIGMA2 | 103,52 | Investment Armington |
| 13. | 3ARM | RE | COM | SIGMA3 | 103,52 | Household Armington |
| 14. | SCET | RE | IND | SIGMA1OUT | 0 | Output Sigma |
| 15. | P021 | RE | HH | FRISCH | -23,25 | Frisch LES parameter |
| 16. | TRAN | RE | TYPE | TRANSFER\_F | 30.990,8 | Gov Trans foreign |
| 17. | GOHH | RE | HH\*TYPE | TRANSFER\_H | 284.107,4 | Gov Trans Household |
| 18. | HINC | RE | HH\*OCC | HINC | 12.672.181 | HH Labor Income |
| 19. | LAND | RE | AGIND\*HH | LANDS | 573.372,6 | household land rental by ind |
| 20. | P018 | RE | COM | EXP\_ELAST | -152,44 | Individual Export Elasticities |
| 21. | 1BAS | RE | COM\*SRC\*IND | V1BAS | 5.200.711 | Intermediate Basic |
| 22. | 2BAS | RE | COM\*SRC\*IND | V2BAS | 1.378.153 | Investment Basic |
| 23. | 2BS\_ | RE | COM\*SRC | V2BASOLD | 1.378.153 | Investment Basic |
| 24. | 2TOT | RE | IND | V2TOT | 1.405.455 | Investment (by IND) |
| 25. | 3BAS | RE | COM\*SRC\*HH | V3BAS | 3.100.906 | Household Basic |
| 26. | 4BAS | RE | COM | V4BAS | 1.460.607 | Export Basic |

Lampiran 3. Komponen data dasar 35 sektor (*lanjutan*)

|  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- |
| No. | Header | Type | Dimension | Coeff | Total | Name |
| 27. | 5BAS | RE | COM\*SRC | V5BAS | 415.977,6 | Government Basic |
| 28. | 6BAS | RE | COM\*SRC | V6BAS | 103.375,2 | Stocks |
| 29. | 1MAR | RE | COM\*SRC\*IND\*MAR | V1MAR | 0 | Intermediate Margins |
| 30. | 2MAR | RE | COM\*SRC\*IND\*MAR | V2MAR | 0 | Investment Margins |
| 31. | 3MAR | RE | COM\*SRC\*MAR\*HH | V3MAR | 0 | House. Margins |
| 32. | 4MAR | RE | COM\*MAR | V4MAR | 0 | Exports Margins |
| 33. | 5MAR | RE | COM\*SRC\*MAR | V5MAR | 0 | Government Margins |
| 34. | 1TAX | RE | COM\*SRC\*IND | V1TAX | 134.998,3 | Tax Intermediate Basic |
| 35. | 2TAX | RE | COM\*SRC\*IND | V2TAX | 27.302,61 | Tax Investment Basic |
| 36. | 2TX\_ | RE | COM\*SRC | V2TAXOLD | 27.302,61 | Investment Tax |
| 37. | 3TAX | RE | COM\*SRC\*HH | V3TAX | 94.898,86 | Tax Hausehold Basic |
| 38. | 4TAX | RE | COM | V4TAX | 26.631,02 | Tax Export Basic |
| 39. | 5TAX | RE | COM\*SRC | V5TAX | 889,1 | TAX Government Basic |
| 40. | 1LAB | RE | IND\*OCC | V1LAB | 1.606.250 | Labour |
| 41. | MAKE | RE | COM\*IND | MAKE | 10.330.397 | Multiproduct Matrix |
| 42. | XPEL | RE | COM\*HH | EPS | 303,48 | Expenditure Elasticity |
| 43. | ALPH | RE | AGRIFAC\*AGRIFAC\*AGIND | BETA\_A | 0 | BETA\_A |
| 44. | TRNL | RE | IND | TRNL | 0 | TRNL |
| 45. | ALP2 | RE | N\_AGRIFAC\*N\_AGRIFAC\*N\_AGRI | BETA\_N | 0 | BETA\_N |
| 46. | PINC | RE | HH | V0HHTAX | 27.247 | Personal Income Tax Collection |
| 47. | P027 | RE | IND | QCOEF | 145,14 | Gross/Net Rate of Return |

Lampiran 4. Nilai PDB Indonesia dari sisi pengeluaran dan sisi pendapatan

(miliar rupiah)

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| No. | Pengeluaran | Nilai | No. | Pendapatan | Nilai |
| 1. | Konsumsi | 3.195.805 | 1. | Lahan | 573.373 |
| 2. | Investasi | 1.405.455 | 2. | Tenaga kerja | 1.606.250 |
| 3. | Pengeluaran pemerintah | 416.867 | 3. | Modal | 3.014.766 |
| 4. | Stok | 103.375 | 4. | Subsidi | -199.702 |
| 5. | Expor | 1.487.238 | 5. | Pajak tidak langsung | 307.486 |
| 6. | Impor | -1.306.567 |  |  |  |
| Total | | 5.302.173 | Total | | 5.302.173 |

Sumber: Tabel I-O 2008 dan SNSE 2008 (diolah)

Lampiran 5. Nilai penjualan sektoral

(miliar rupiah)

|  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- |
| Sektor | Produk antara domestik | Investasi | Konsumsi RT | Ekspor | Pengeluaran pemerintah | Stok | Total |
| 1. Padi | 164.956 | 0 | 0 | 0 | 0 | 3.027 | 167.983 |
| 2.TanMakLn | 110.619 | 5 | 200.215 | 658 | 0 | -12.507 | 298.990 |
| 3. Karet | 34.693 | 212 | 0 | 95 | 0 | 807 | 35.807 |
| 4. Tebu | 10.117 | 0 | 63 | 1 | 0 | 113 | 10.293 |
| 5. KelapaSawit | 76.717 | 684 | 0 | 298 | 0 | -700 | 76.999 |
| 6. Tembakau | 3.362 | 0 | 717 | 0 | 0 | -151 | 3.928 |
| 7. Kopi | 3.998 | 187 | 644 | 6.600 | 0 | -726 | 10.702 |
| 8. Teh | 844 | 12 | 129 | 23 | 0 | -2 | 1.005 |
| 9. Kakao | 1.158 | 9 | 178 | 6.894 | 0 | 119 | 8.358 |
| 10. TanKebLn | 39.898 | 338 | 10.810 | 4.439 | 0 | -351 | 55.133 |
| 11. Peternakan | 138.038 | 735 | 133.555 | 426 | 0 | -8.139 | 264.614 |
| 12. Kayu | 38.219 | 0 | 1.966 | 113 | 0 | 2.229 | 42.527 |
| 13. HasHutln | 5.818 | 0 | 3.173 | 287 | 0 | 477 | 9.755 |
| 14. Perikanan | 72.228 | 0 | 111.657 | 2.829 | 0 | -4.588 | 182.126 |
| 15. Pertambangan | 389.470 | 959 | 1.042 | 235.277 | 0 | 67.021 | 693.769 |
| 16. Makanan | 112.207 | 0 | 163.562 | 27.448 | 0 | -1.305 | 301.913 |
| 17. IndKlpSwt | 57.066 | 0 | 18.151 | 130.005 | 0 | -10.498 | 194.724 |
| 18. Beras | 54.749 | 0 | 196.761 | 187 | 0 | -14.568 | 237.128 |
| 19. Terigu | 39.845 | 0 | 59.146 | 3.035 | 0 | 351 | 102.377 |
| 20. Gula | 12.982 | 0 | 9.173 | 254 | 0 | 130 | 22.539 |

Lampiran 5. Nilai penjualan sektoral (*lanjutan*)

(miliar rupiah)

|  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- |
| Sektor | Produk antara domestik | Investasi | Konsumsi RT | Ekspor | Pengeluaran pemerintah | Stok | Total |
| 21. Minuman | 3.830 | 0 | 12.666 | 246 | 0 | -750 | 15.993 |
| 22. Rokok | 6.855 | 0 | 63.899 | 2.466 | 0 | 402 | 73.621 |
| 23. Pemintalan | 21.963 | 0 | 430 | 16.788 | 0 | -497 | 38.685 |
| 24. TeksPakKlt | 70.765 | 164 | 86.102 | 84.960 | 0 | 12.302 | 254.293 |
| 25. BambuKyRotan | 97.821 | 137 | 33.058 | 37.445 | 0 | 4.144 | 172.606 |
| 26. KrtsKrbon | 89.917 | 0 | 15.122 | 40.187 | 0 | 140 | 145.367 |
| 27. PpkPestisida | 43.188 | 0 | 767 | 2.908 | 0 | 2.119 | 48.982 |
| 28. Kimia | 188.448 | 0 | 62.115 | 55.632 | 0 | -26.809 | 279.386 |
| 29. OlahKaret | 50.330 | 0 | 7.539 | 54.335 | 0 | 295 | 112.499 |
| 30. Semen | 34.083 | 0 | 0 | 699 | 0 | 568 | 35.351 |
| 31. IndustriLain | 795.674 | 84.281 | 333.195 | 429.965 | 0 | 27.106 | 1.670.221 |
| 32. ListrkGasAir | 81.692 | 0 | 37.337 | 0 | 0 | 0 | 119.029 |
| 33. Bangunan | 98.558 | 1.129.077 | 0 | 0 | 0 | 0 | 1.227.635 |
| 34. DagResHot | 478.337 | 37.695 | 603.718 | 186.286 | 0 | 3.638 | 1.309.674 |
| 35. Jasa | 877.761 | 27.668 | 658.394 | 129.822 | 411.823 | 918 | 2.106.386 |
| Total | 4.306.204 | 1.282.165 | 2.825.282 | 1.460.607 | 411.823 | 44.315 | 10.330.397 |

Sumber: Tabel I-O 2008 dan SNSE 2008 (diolah)

Lampiran 6. Biaya produksi sektoral

(miliar rupiah)

|  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- |
| Sektor | Input antara domestik | Input antara impor | Pajak tak langsung | Upah/Gaji | Kapital | Lahan | Pajak produksi | Total |
| 1. Padi | 34.698 | 7.864 | 764 | 21.866 | 1.068 | 102.332 | -609 | 167.983 |
| 2. TanMakLn | 41.152 | 5.558 | 705 | 42.685 | 2.161 | 207.007 | -278 | 298.990 |
| 3. Karet | 11.780 | 421 | 135 | 12.173 | 614 | 10.684 | 0 | 35.807 |
| 4. Tebu | 2.643 | 523 | 51 | 2.441 | 252 | 4.382 | 0 | 10.293 |
| 5. KelapaSawit | 26.462 | 7.386 | 621 | 13.457 | 1.580 | 27.493 | 0 | 76.999 |
| 6. Tembakau | 2.010 | 91 | 21 | 744 | 58 | 1.005 | 0 | 3.928 |
| 7. Kopi | 3.949 | 116 | 46 | 1.680 | 267 | 4.645 | 0 | 10.702 |
| 8. Teh | 146 | 11 | 2 | 305 | 29 | 513 | 0 | 1.005 |
| 9. Kakao | 1.946 | 116 | 19 | 1.159 | 278 | 4.840 | 0 | 8.358 |
| 10. TanKebLn | 14.370 | 417 | 163 | 9.504 | 1.667 | 29.012 | 0 | 55.133 |
| 11. Peternakan | 127.582 | 5.614 | 2.149 | 43.402 | 29.295 | 56.572 | 0 | 264.614 |
| 12. Kayu | 9.116 | 801 | 162 | 7.111 | 5.738 | 19.599 | 0 | 42.527 |
| 13. HasHutln | 1.917 | 123 | 29 | 1.746 | 1.345 | 4.595 | 0 | 9.755 |
| 14. Perikanan | 44.747 | 3.105 | 568 | 26.451 | 6.659 | 100.694 | -98 | 182.126 |
| 15. Pertambangan | 115.221 | 24.593 | 3.215 | 83.499 | 467.241 | 0 | 0 | 693.769 |
| 16. Makanan | 195.811 | 9.538 | 3.089 | 27.682 | 65.793 | 0 | 0 | 301.913 |
| 17. IndKlpSwt | 125.444 | 522 | 1.275 | 23.539 | 43.944 | 0 | 0 | 194.724 |
| 18. Beras | 182.428 | 61 | 2.041 | 10.564 | 42.033 | 0 | 0 | 237.128 |
| 19. Terigu | 49.539 | 21.144 | 2.285 | 9.417 | 19.992 | 0 | 0 | 102.377 |
| 20. Gula | 16.357 | 238 | 275 | 1.957 | 3.711 | 0 | 0 | 22.539 |

Lampiran 6. Biaya produksi sektoral (*lanjutan*)

(miliar rupiah)

|  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- |
| Sektor | Input antara domestik | Input antara impor | Pajak tak langsung | Upah/Gaji | Kapital | Lahan | Pajak Produksi | Total |
| 21. Minuman | 10.314 | 551 | 260 | 2.024 | 2.844 | 0 | 0 | 15.993 |
| 22. Rokok | 32.971 | 7.972 | 3.690 | 8.758 | 20.231 | 0 | 0 | 73.621 |
| 23. Pemintalan | 15.808 | 9.345 | 2.014 | 2.527 | 8.992 | 0 | 0 | 38.685 |
| 24. TeksPakKlt | 133.531 | 17.918 | 5.044 | 33.404 | 64.396 | 0 | 0 | 254.293 |
| 25. BambuKyRotan | 90.098 | 8.680 | 2.262 | 20.355 | 51.210 | 0 | 0 | 172.606 |
| 26. KrtsKrbon | 73.564 | 17.121 | 2.607 | 15.752 | 36.322 | 0 | 0 | 145.367 |
| 27. PpkPestisida | 26.757 | 4.633 | 1.489 | 11.994 | 19.272 | 0 | -15.164 | 48.982 |
| 28. Kimia | 129.599 | 64.800 | 7.721 | 26.487 | 50.778 | 0 | 0 | 279.386 |
| 29. OlahKaret | 66.811 | 10.099 | 2.191 | 12.818 | 20.579 | 0 | 0 | 112.499 |
| 30. Semen | 19.421 | 1.355 | 728 | 4.127 | 9.720 | 0 | 0 | 35.351 |
| 31. IndustriLain | 620.982 | 348.275 | 39.175 | 201.702 | 558.004 | 0 | -97.917 | 1.670.221 |
| 32. ListrkGasAir | 69.626 | 7.021 | 1.809 | 31.571 | 92.909 | 0 | -83.907 | 119.029 |
| 33. Bangunan | 643.203 | 128.166 | 20.964 | 167.856 | 267.445 | 0 | 0 | 1.227.635 |
| 34. DagResHot | 596.671 | 43.014 | 10.929 | 204.971 | 454.090 | 0 | 0 | 1.309.674 |
| 35. Jasa | 769.529 | 137.315 | 16.500 | 520.521 | 664.249 | 0 | -1.729 | 2.106.386 |
| Total | 4.306.204 | 894.507 | 134.998 | 1.606.250 | 3.014.766 | 573.373 | -199.702 | 10.330.397 |

Sumber: Tabel I-O 2008 dan SNSE 2008 (diolah)